Closest-pair problem
The aim of this task is to provide a function to find the closest two points among a set of given points in two dimensions, i.e. to solve the Closest pair of points problem in the planar case.
You are encouraged to solve this task according to the task description, using any language you may know.
| This page uses content from Wikipedia. The original article was at Closest-pair problem. The list of authors can be seen in the page history. As with Rosetta Code, the text of Wikipedia is available under the GNU FDL. (See links for details on variance) |
The straightforward solution is a O(n2) algorithm (which we can call brute-force algorithm); the pseudocode (using indexes) could be simply:
bruteForceClosestPair of P(1), P(2), ... P(N), N > 1
minDistance ← |P(1) - P(2)|
foreach i ∈ [1, N-1]
foreach j ∈ [i+1, N]
if |P(i) - P(j)| < minDistance then
minDistance ← |P(i) - P(j)|
endif
return minDistance
A better algorithm is based on the recursive divide&conquer approach, as explained also at Wikipedia, which is O(n log n); a pseudocode could be:
closestPair of P(1), P(2), ... P(N), N > 1
if N ≤ 3 then
return closest points of P using brute-force algorithm
else
xP ← P ordered by the x coordinate, in ascending order
PL ← points of xP from 1 to ⌊N/2⌋
PR ← points of xP from ⌊N/2⌋+1 to N
if number of points in PL is odd then
append xP(⌊N/2⌋+1) to PL
endif
if number of points in PR is odd then
prepend xP(⌊N/2⌋) to PR
endif
dL ← ClosestPair of PL
dR ← ClosestPair of PR
dmin ← min{dL, dR}
xM ← (xP(⌊N/2⌋+1) - xP(⌊N/2⌋)) / 2
S ← { p ∈ P : |xM - px| < dmin }
yP ← S ordered by the y coordinate, in ascending order
closest ← ∞
nP ← number of points in yP
for i from 1 to nP
for j from max{i-3, 1} to min{nP, i+3}
if i ≠ j then
if |yP(i) - yP(j)| < closest then
closest ← |yP(i) - yP(j)|
endif
endif
endfor
endfor
endif
Notes
- The pseudocode works with at least two points. It could be rewritten so that a single point is treated like if we want to know the distance from it and a point at infinity (i.e. the distance is infinity)
References
Smalltalk
These class methods return a three elements array, where the first two items are the points, while the third is the distance between them (which having the two points, can be computed; but it was easier to keep it already computed in the third position of the array).
<lang smalltalk>Object subclass: ClosestPair [
ClosestPair class >> raiseInvalid: arg [
SystemExceptions.InvalidArgument
signalOn: arg
reason: 'specify at least two points'
]
ClosestPair class >> bruteForce: pointsList [ |dist from to points|
(pointsList size < 2) ifTrue: [ self raiseInvalid: pointsList ].
points := pointsList asOrderedCollection.
from := points at: 1. to := points at: 2.
dist := from dist: to.
[ points isEmpty ]
whileFalse: [ |p0|
p0 := points removeFirst.
points do: [ :p |
((p0 dist: p) <= dist)
ifTrue: [ from := p0. to := p. dist := p0 dist: p. ]
]
].
^ { from. to. from dist: to }
]
ClosestPair class >> orderByX: points [ ^ points asSortedCollection: [:a :b| (a x) < (b x) ] ] ClosestPair class >> orderByY: points [ ^ points asSortedCollection: [:a :b| (a y) < (b y) ] ]
ClosestPair class >> splitLeft: pointsList [ |s| s := pointsList size // 2. s odd ifTrue: [ s := s + 1 ]. ^ pointsList copyFrom: 1 to: s ] ClosestPair class >> splitRight: pointsList [ |s| s := (pointsList size) - (pointsList size // 2). s odd ifTrue: [ s := s - 1 ]. ^ pointsList copyFrom: s to: (pointsList size). ]
ClosestPair class >> minBetween: a and: b [
(a at: 3) < (b at: 3)
ifTrue: [ ^a ]
ifFalse: [ ^b ]
]
ClosestPair class >> recursiveDAndC: pointsList [
|orderedByX pR pL minL minR minDist middleVLine joiningStrip tDist|
(pointsList size < 2) ifTrue: [ self raiseInvalid: pointsList ].
(pointsList size <= 3)
ifTrue: [ ^ self bruteForce: pointsList ].
orderedByX := self orderByX: pointsList.
pR := self splitLeft: orderedByX.
pL := self splitRight: orderedByX.
minR := self recursiveDAndC: pR.
minL := self recursiveDAndC: pL.
minDist := self minBetween: minR and: minL.
middleVLine := (((orderedByX at: (orderedByX size)//2+1) x) +
((orderedByX at: (orderedByX size)//2) x)) / 2.
joiningStrip := self
orderByY: (pointsList
select: [ :p |
((middleVLine - (p x)) abs) < (minDist at: 3)
]
).
tDist := { nil. nil.
FloatD infinity
}.
1 to: (joiningStrip size) do: [ :i |
((i-3) max: 1)
to: ((i+3) min: (joiningStrip size))
do: [ :j |
j ~= i ifTrue: [ |t|
t := (joiningStrip at: i) dist: (joiningStrip at: j).
t < (tDist at:3 )
ifTrue: [
tDist := { joiningStrip at: i.
joiningStrip at: j.
t }.
]
]
]
].
^ self minBetween: minDist and: tDist
]
].</lang>
Testing
<lang smalltalk>|coll cp ran| "Let's use the same seed to be sure of the results..." ran := Random seed: 100.
coll := (1 to: 10000 collect: [ :a |
Point x: (ran next)*10 y: (ran next)*10 ]).
cp := ClosestPair bruteForce: coll. ((cp at: 3) asScaledDecimal: 7) displayNl.
"or"
cp := ClosestPair recursiveDAndC: coll. ((cp at: 3) asScaledDecimal: 7) displayNl.</lang>
The brute-force approach with 10000 points, run with the time tool, gave
224.21user 1.31system 3:46.84elapsed 99%CPU
while the recursive divide&conquer algorithm gave
4.65user 0.00system 0:05.07elapsed 91%CPU
(Of course these results must be considered relative and taken cum grano salis; time counts also the time taken to initialize the Smalltalk environment, and I've taken no special measures to avoid the system load falsifying the results)