Rosetta Code

Sutherland-Hodgman polygon clipping: Difference between revisions

Page Discussion

Sutherland-Hodgman polygon clipping (view source)

Revision as of 11:16, 11 February 2024

46,019 bytes added ,  3 months ago
m
→‎{{header|Wren}}: Changed to Wren S/H
m (→‎{{header|Wren}}: Changed to Wren S/H)
 
(16 intermediate revisions by 2 users not shown)
Line 1,824:
(100, 250)
</pre>
 
=={{header|Common Lisp}}==
{{trans|Scheme}}
<syntaxhighlight lang="lisp">
;;; Sutherland-Hodgman polygon clipping.
 
(defun evaluate-line (x1 y1 x2 y2 x)
;; Given the straight line between (x1,y1) and (x2,y2), evaluate it
;; at x.
(let ((dy (- y2 y1))
(dx (- x2 x1)))
(let ((slope (/ dy dx))
(intercept (/ (- (* dx y1) (* dy x1)) dx)))
(+ (* slope x) intercept))))
 
(defun intersection-of-lines (x1 y1 x2 y2 x3 y3 x4 y4)
;; Given the line between (x1,y1) and (x2,y2), and the line between
;; (x3,y3) and (x4,y4), find their intersection.
(cond ((= x1 x2) (list x1 (evaluate-line x3 y3 x4 y4 x1)))
((= x3 x4) (list x3 (evaluate-line x1 y1 x2 y2 x3)))
(t (let ((denominator (- (* (- x1 x2) (- y3 y4))
(* (- y1 y2) (- x3 x4))))
(x1*y2-y1*x2 (- (* x1 y2) (* y1 x2)))
(x3*y4-y3*x4 (- (* x3 y4) (* y3 x4))))
(let ((xnumerator (- (* x1*y2-y1*x2 (- x3 x4))
(* (- x1 x2) x3*y4-y3*x4)))
(ynumerator (- (* x1*y2-y1*x2 (- y3 y4))
(* (- y1 y2) x3*y4-y3*x4))))
(list (/ xnumerator denominator)
(/ ynumerator denominator)))))))
 
(defun intersection-of-edges (e1 e2)
;;
;; A point is a list of two coordinates, and an edge is a list of
;; two points.
;;
(let ((point1 (car e1))
(point2 (cadr e1))
(point3 (car e2))
(point4 (cadr e2)))
(let ((x1 (car point1))
(y1 (cadr point1))
(x2 (car point2))
(y2 (cadr point2))
(x3 (car point3))
(y3 (cadr point3))
(x4 (car point4))
(y4 (cadr point4)))
(intersection-of-lines x1 y1 x2 y2 x3 y3 x4 y4))))
 
(defun point-is-left-of-edge-p (pt edge)
(let ((x (car pt))
(y (cadr pt))
(x1 (caar edge))
(y1 (cadar edge))
(x2 (caadr edge))
(y2 (cadadr edge)))
;; Outer product of the vectors (x1,y1)-->(x,y) and
;; (x1,y1)-->(x2,y2)
(< (- (* (- x x1) (- y2 y1))
(* (- x2 x1) (- y y1)))
0)))
 
(defun clip-subject-edge (subject-edge clip-edge accum)
(flet ((intersect ()
(intersection-of-edges subject-edge clip-edge)))
(let ((s1 (car subject-edge))
(s2 (cadr subject-edge)))
(let ((s2-is-inside (point-is-left-of-edge-p s2 clip-edge))
(s1-is-inside (point-is-left-of-edge-p s1 clip-edge)))
(if s2-is-inside
(if s1-is-inside
(cons s2 accum)
(cons s2 (cons (intersect) accum)))
(if s1-is-inside
(cons (intersect) accum)
accum))))))
 
(defun for-each-subject-edge (i subject-points clip-edge accum)
(let ((n (length subject-points))
(accum '()))
(loop for i from 0 to (1- n)
do (let ((s2 (aref subject-points i))
(s1 (aref subject-points
(- (if (zerop i) n i) 1))))
(setf accum (clip-subject-edge (list s1 s2)
clip-edge accum))))
(coerce (reverse accum) 'vector)))
 
(defun for-each-clip-edge (i subject-points clip-points)
(let ((n (length clip-points)))
(loop for i from 0 to (1- n)
do (let ((c2 (aref clip-points i))
(c1 (aref clip-points (- (if (zerop i) n i) 1))))
(setf subject-points
(for-each-subject-edge 0 subject-points
(list c1 c2) '()))))
subject-points))
 
(defun clip (subject-points clip-points)
(for-each-clip-edge 0 subject-points clip-points))
 
(defun write-eps (outf subject-points clip-points result-points)
(flet ((x (pt) (coerce (car pt) 'float))
(y (pt) (coerce (cadr pt) 'float))
(code (s)
(princ s outf)
(terpri outf)))
(flet ((moveto (pt)
(princ (x pt) outf)
(princ " " outf)
(princ (y pt) outf)
(princ " moveto" outf)
(terpri outf))
(lineto (pt)
(princ (x pt) outf)
(princ " " outf)
(princ (y pt) outf)
(princ " lineto" outf)
(terpri outf))
(setrgbcolor (rgb)
(princ rgb outf)
(princ " setrgbcolor" outf)
(terpri outf))
(closepath () (code "closepath"))
(fill-it () (code "fill"))
(stroke () (code "stroke"))
(gsave () (code "gsave"))
(grestore () (code "grestore")))
(flet ((showpoly (poly line-color fill-color)
(let ((n (length poly)))
(moveto (aref poly 0))
(loop for i from 1 to (1- n)
do (lineto (aref poly i)))
(closepath)
(setrgbcolor line-color)
(gsave)
(setrgbcolor fill-color)
(fill-it)
(grestore)
(stroke))))
 
(code "%!PS-Adobe-3.0 EPSF-3.0")
(code "%%BoundingBox: 40 40 360 360")
(code "0 setlinewidth")
(showpoly clip-points ".5 0 0" "1 .7 .7")
(showpoly subject-points "0 .2 .5" ".4 .7 1")
(code "2 setlinewidth")
(code "[10 8] 0 setdash")
(showpoly result-points ".5 0 .5" ".7 .3 .8")
(code "%%EOF")))))
 
(defun write-eps-to-file (outfile subject-points clip-points
result-points)
(with-open-file (outf outfile :direction :output
:if-exists :supersede
:if-does-not-exist :create)
(write-eps outf subject-points clip-points result-points)))
 
(defvar subject-points
#((50 150)
(200 50)
(350 150)
(350 300)
(250 300)
(200 250)
(150 350)
(100 250)
(100 200)))
 
(defvar clip-points
#((100 100)
(300 100)
(300 300)
(100 300)))
 
(defvar result-points (clip subject-points clip-points))
 
(princ result-points)
(terpri)
(write-eps-to-file "sutherland-hodgman.eps"
subject-points clip-points result-points)
(princ "Wrote sutherland-hodgman.eps")
(terpri)</syntaxhighlight>
{{out}}
<pre>$ clisp sutherland-hodgman.lisp
#((100 350/3) (125 100) (275 100) (300 350/3) (300 300) (250 300) (200 250) (175 300) (125 300) (100 250))
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-cl.png|alt=The polygons as generated by Common Lisp.]]
 
=={{header|D}}==
Line 2,014 ⟶ 2,203:
%{x: 100.0, y: 250.0}
</pre>
 
=={{header|Evaldraw}}==
{{trans|C}}
This is losely based on the C version. Since Evaldraw doesnt have dynamic memory, all sizes must be declared up front. We limit ourselves to polygons of up to 32 vertices. This is fine, as the input polygon with its 9 vertices, when clipped against the clipper rectangle only produces a 11 vertex polygon. If we run out of vertices at runtime, the errno function is called and displays an error number.
[[File:Evaldraw sutherland hodgman.png|thumb|alt=An 9 vertex polygon clipped against a rectangle|Shows input subject polygon vert count and output vert count]]
<syntaxhighlight lang="c">
struct vec{ x, y; };
enum{MAX_POLY_VERTS=32};
enum{NUM_RECT_VERTS=4, NUM_SUBJECT_VERTS=9}
struct poly_t{
len; // number of vertices
vec v[MAX_POLY_VERTS]; // wrap array of vertices inside struct
};
()
{
vec subject_verts[NUM_SUBJECT_VERTS] = { 50,150, 200,50, 350,150, 350,300,250,300,200,250, 150,350,100,250,100,200 };
vec rectangle_vertices[NUM_RECT_VERTS] = {100,100, 300,100, 300,300, 100,300};
poly_t clipper; // This polygon will define the valid area
clipper.len = 0;
for(i=0; i<NUM_RECT_VERTS; i++) {
poly_append( clipper, rectangle_vertices[i] );
}
poly_t subject; // This polygon will be clipped so its contained within the valid area.
subject.len = 0;
for(i=0; i<NUM_SUBJECT_VERTS; i++) {
poly_append( subject, subject_verts[i] );
}
poly_t clipped_result; poly_clip(subject, clipper, clipped_result);
cls(0);
setcol(255,255,255); drawpoly(clipper, 0);
setcol(255,0,255); drawpoly(subject, 0);
setcol(255,255,0); drawpoly(clipped_result, 1);
moveto(0,0); printf("%g in\n%2.0f out", subject.len, clipped_result.len);
}
poly_clip(poly_t subject, poly_t clip, poly_t pout) {
dir = poly_winding(clip);
// Clip all subject edges against first edge in clipper
poly_t p0; // current set of clipped edges
poly_t p1; // next set of clipped edges
p1.len = 0; // Clear p1
poly_edge_clip(subject, clip.v[clip.len - 1], clip.v[0], dir, p1);
for (i = 0; i < clip.len - 1; i++) { // Visit each edge in the clip polygon
poly_copy(p1,p0); // Copy p1 into p0. We could also have done p0=p1.
p1.len = 0; // Clear p1
poly_edge_clip(p0, clip.v[i], clip.v[i+1], dir, p1);
if(p1.len == 0) break; // no vertices in output, finished.
}
pout = p1;
}
poly_winding(poly_t p) {
return left_of(p.v[0], p.v[1], p.v[2]);
}
poly_edge_clip(poly_t subject, vec clip0, vec clip1, left, poly_t res) {
vec v0; v0 = subject.v[subject.len - 1];
if (res.len != 0) errno(200); // Expect empty result so far
side0 = left_of(clip0, clip1, v0);
if (side0 != -left) { poly_append(res, v0); }
 
// Intersect subject edge v0-v1 against clipper edge clip0-clip1
for (i = 0; i < subject.len; i++) {
vec v1; v1 = subject.v[i];
side1 = left_of(clip0, clip1, v1);
// side0+side1==0 means v0 and v1 cross the edge. v0 is inside.
if ( (side0 + side1 == 0) && side0) {
vec isect; if (line_sect(clip0, clip1, v0, v1, isect)) poly_append(res, isect);
}
if (i == subject.len - 1) break; // Back to last, finished
if (side1 != -left) { poly_append(res, v1); } // add v1 to poly
v0 = v1;
side0 = side1;
}
}
poly_append(poly_t p, vec v) {
p.v[p.len++] = v;
if(p.len>MAX_POLY_VERTS) errno(100);
}
poly_copy(poly_t src, poly_t dst) { // This improves on assigning dst to src as
for(i=0; i<src.len; i++) { // only necessary amount of vertices are copied.
dst.v[i] = src.v[i];
}
dst.len = src.len;
}
left_of(vec a, vec b, vec c) {
vec ab; vsub(ab, b, a);
vec bc; vsub(bc, c, b);
return sgn( cross2D(ab, bc) ); // return 1 if ab is left side of c. -1 if right. 0 if colinear.
}
line_sect(vec a0, vec a1, vec b0, vec b1, vec isect) {
vec da; vsub(da,a1,a0);
vec db; vsub(db,b1,b0);
vec d; vsub(d,a0, b0);
/* a0+t da = b0+s db -> a0 X da = b0 X da + s db X da -> s = (a0 - b0) X da / (db X da) */
double dbXda = cross2D(db, da);
if (!dbXda) return 0;
s = cross2D(&d, &da) / dbXda;
if (s <= 0 || s >= 1) return 0;
isect.x = b0.x + s * db.x;
isect.y = b0.y + s * db.y;
return 1;
}
errno(code) { // Since we dont have asserts, halt and print an error code
while(1) {
cls(32,32,32); setcol(200,0,0); moveto(0,0);
printf("errno(%g)", code); refresh(); sleep(1);
}
}
drawpoly(poly_t p, show_verts) {
for(i=0; i<p.len+1; i++) {
vec v = p.v[i%p.len];
if (show_verts) for(j=0; j<32; j++) { setpix( v.x+nrnd, v.y+nrnd); }
if(i==0) moveto(v.x,v.y); else lineto(v.x,v.y);
}
}
// 2D cross product - also known as directed area product.
cross2D(vec a, vec b) { return a.x * b.y - a.y * b.x; }
vsub(vec c, vec a, vec b) { c.x = a.x - b.x; c.y = a.y - b.y; }
</syntaxhighlight>
 
=={{header|Fortran}}==
Line 3,107 ⟶ 3,419:
>> axis square</syntaxhighlight>
[[File:Sutherland-Hodgman_MATLAB.png]]
 
=={{header|Mercury}}==
{{trans|ATS}}
{{works with|Mercury|22.01.1}}
<syntaxhighlight lang="mercury">
:- module sutherland_hodgman_task.
 
:- interface.
:- import_module io.
:- pred main(io::di, io::uo) is det.
 
:- implementation.
:- import_module exception.
:- import_module float.
:- import_module list.
:- import_module pair.
:- import_module string.
 
:- type plane_point == pair(float).
:- func xcoord(plane_point) = float.
:- func ycoord(plane_point) = float.
:- func plane_point(float, float) = plane_point.
:- pred write_plane_point(plane_point::in, io::di, io::uo) is det.
:- pred write_plane_point_list(list(plane_point)::in, string::in,
io::di, io::uo) is det.
xcoord(Pt) = fst(Pt).
ycoord(Pt) = snd(Pt).
plane_point(X, Y) = pair(X, Y).
write_plane_point(Pt, !IO) :-
write_string("(", !IO),
write_float(xcoord(Pt), !IO),
write_string(", ", !IO),
write_float(ycoord(Pt), !IO),
write_string(")", !IO).
write_plane_point_list(Pts, Separator, !IO) :-
write_list(Pts, Separator, write_plane_point, !IO).
 
:- type plane_edge == pair(plane_point).
:- func point0(plane_edge) = plane_point.
:- func point1(plane_edge) = plane_point.
:- func plane_edge(plane_point, plane_point) = plane_edge.
point0(Edge) = fst(Edge).
point1(Edge) = snd(Edge).
plane_edge(Pt0, Pt1) = pair(Pt0, Pt1).
 
:- func evaluate_line(float, float, float, float, float) = float.
evaluate_line(X1, Y1, X2, Y2, X) = Y :-
%% Given the line (X1,Y1)--(X2,Y2), evaluate it at X.
Dy = Y2 - Y1,
Dx = X2 - X1,
Slope = Dy / Dx,
Intercept = ((Dx * Y1) - (Dy * X1)) / Dx,
Y = (Slope * X) + Intercept.
 
:- func intersection_of_lines(float, float, float, float,
float, float, float, float)
= plane_point.
intersection_of_lines(X1, Y1, X2, Y2, X3, Y3, X4, Y4) = Pt :-
%% Given the lines (X1,Y1)--(X2,Y2) and (X3,Y3)--(X3,Y4), find their
%% point of intersection.
(if (X1 = X2)
then (Pt = plane_point(X1, evaluate_line(X3, Y3, X4, Y4, X1)))
else if (X3 = X4)
then (Pt = plane_point(X3, evaluate_line(X1, Y1, X2, Y2, X3)))
else (Pt = plane_point(X, Y),
X = Xnumerator / Denominator,
Y = Ynumerator / Denominator,
Denominator =
((X1 - X2) * (Y3 - Y4)) - ((Y1 - Y2) * (X3 - X4)),
Xnumerator =
(X1Y2_Y1X2 * (X3 - X4)) - ((X1 - X2) * X3Y4_Y3X4),
Ynumerator =
(X1Y2_Y1X2 * (Y3 - Y4)) - ((Y1 - Y2) * X3Y4_Y3X4),
X1Y2_Y1X2 = (X1 * Y2) - (Y1 * X2),
X3Y4_Y3X4 = (X3 * Y4) - (Y3 * X4))).
 
:- func intersection_of_edges(plane_edge, plane_edge) = plane_point.
intersection_of_edges(E1, E2) = Pt :-
%% Given two edges, find their point of intersection (on the
%% assumption that there is such an intersection).
Pt = intersection_of_lines(X1, Y1, X2, Y2, X3, Y3, X4, Y4),
Pt1 = point0(E1), Pt2 = point1(E1),
Pt3 = point0(E2), Pt4 = point1(E2),
X1 = xcoord(Pt1), Y1 = ycoord(Pt1),
X2 = xcoord(Pt2), Y2 = ycoord(Pt2),
X3 = xcoord(Pt3), Y3 = ycoord(Pt3),
X4 = xcoord(Pt4), Y4 = ycoord(Pt4).
 
:- pred point_is_left_of_edge(plane_point::in, plane_edge::in)
is semidet.
point_is_left_of_edge(Pt, Edge) :-
%% Is Pt left of Edge?
(OP < 0.0),
%% OP = outer product of the vectors (x1,y1)-->(x,y) and
%% (x1,y1)-->(x2,y2). *)
OP = ((X - X1) * (Y2 - Y1)) - ((X2 - X1) * (Y - Y1)),
Pt1 = point0(Edge), Pt2 = point1(Edge),
X1 = xcoord(Pt1), Y1 = ycoord(Pt1),
X2 = xcoord(Pt2), Y2 = ycoord(Pt2),
X = xcoord(Pt), Y = ycoord(Pt).
 
:- func clip_subject_edge(plane_edge, plane_edge,
list(plane_point)) = list(plane_point).
clip_subject_edge(Subject_edge, Clip_edge, Accum0) = Accum :-
S1 = point0(Subject_edge), S2 = point1(Subject_edge),
(if (point_is_left_of_edge(S2, Clip_edge))
then (if (point_is_left_of_edge(S1, Clip_edge))
then (Accum = [S2 | Accum0])
else (Accum = [S2, Intersection | Accum0],
Intersection =
intersection_of_edges(Subject_edge, Clip_edge)))
else (if (point_is_left_of_edge(S1, Clip_edge))
then (Accum = [Intersection | Accum0],
Intersection =
intersection_of_edges(Subject_edge, Clip_edge))
else (Accum = Accum0))).
 
:- func plane_points_to_plane_edges(list(plane_point))
= list(plane_edge).
plane_points_to_plane_edges(Pts) = Edges :-
plane_points_to_plane_edges_(Pt_first, Pts, [], Edges),
Pt_first = det_head(Pts).
 
:- pred plane_points_to_plane_edges_(plane_point::in,
list(plane_point)::in,
list(plane_edge)::in,
list(plane_edge)::out) is det.
%% Convert a list of points to a list of edges.
plane_points_to_plane_edges_(Pt_first, [Pt0, Pt1 | Rest],
Edges0, Edges) :-
plane_points_to_plane_edges_(Pt_first, [Pt1 | Rest],
[plane_edge(Pt0, Pt1) | Edges0],
Edges).
plane_points_to_plane_edges_(Pt_first, [Pt_last], Edges0, Edges) :-
Edges = [plane_edge(Pt_last, Pt_first) | reverse(Edges0)].
plane_points_to_plane_edges_(_, [], _, _) :-
throw("list(plane_point) was expected to have length >= 2").
 
:- pred for_each_subject_edge(list(plane_edge)::in, plane_edge::in,
list(plane_point)::in,
list(plane_point)::out) is det.
for_each_subject_edge([], _, Accum0, Accum) :-
(Accum = reverse(Accum0)).
for_each_subject_edge([Subject_edge | Rest], Clip_edge,
Accum0, Accum) :-
Accum1 = clip_subject_edge(Subject_edge, Clip_edge, Accum0),
for_each_subject_edge(Rest, Clip_edge, Accum1, Accum).
 
:- func clip_subject_with_clip_edge(list(plane_point), plane_edge)
= list(plane_point).
clip_subject_with_clip_edge(Subject_pts, Clip_edge) = Pts :-
for_each_subject_edge(Subject_edges, Clip_edge, [], Pts),
Subject_edges = plane_points_to_plane_edges(Subject_pts).
 
:- pred for_each_clip_edge(list(plane_point)::in,
list(plane_point)::out,
list(plane_edge)::in) is det.
for_each_clip_edge(Subject_pts0, Subject_pts, []) :-
(Subject_pts = Subject_pts0).
for_each_clip_edge(Subject_pts0, Subject_pts,
[Clip_edge | Rest]) :-
Subject_pts1 = clip_subject_with_clip_edge(Subject_pts0, Clip_edge),
for_each_clip_edge(Subject_pts1, Subject_pts, Rest).
 
:- func clip(list(plane_point), list(plane_point))
= list(plane_point).
clip(Subject_pts, Clip_pts) = Result_pts :-
for_each_clip_edge(Subject_pts, Result_pts, Clip_edges),
Clip_edges = plane_points_to_plane_edges(Clip_pts).
 
:- pred moveto(text_output_stream::in, plane_point::in,
io::di, io::uo) is det.
moveto(Stream, Pt, !IO) :-
write_float(Stream, xcoord(Pt), !IO),
write_string(Stream, " ", !IO),
write_float(Stream, ycoord(Pt), !IO),
write_string(Stream, " moveto\n", !IO).
 
:- pred lineto(plane_point::in, io::di, io::uo) is det.
lineto(Pt, !IO) :-
write_float(xcoord(Pt), !IO),
write_string(" ", !IO),
write_float(ycoord(Pt), !IO),
write_string(" lineto\n", !IO).
 
:- pred setrgbcolor(text_output_stream::in,
string::in, io::di, io::uo) is det.
setrgbcolor(Stream, Color, !IO) :-
write_string(Stream, Color, !IO),
write_string(Stream, " setrgbcolor\n", !IO).
 
:- pred write_polygon(text_output_stream::in,
list(plane_point)::in,
string::in, string::in,
io::di, io::uo) is det.
write_polygon(Stream, Pts, Line_color, Fill_color, !IO) :-
if ([First_pt | Rest] = Pts)
then (moveto(Stream, First_pt, !IO),
write_list(Stream, Rest, "", lineto, !IO),
write_string(Stream, "closepath\n", !IO),
setrgbcolor(Stream, Line_color, !IO),
write_string(Stream, "gsave\n", !IO),
setrgbcolor(Stream, Fill_color, !IO),
write_string(Stream, "fill\n", !IO),
write_string(Stream, "grestore\n", !IO),
write_string(Stream, "stroke\n", !IO))
else true.
 
:- pred write_eps(text_output_stream::in,
list(plane_point)::in,
list(plane_point)::in,
list(plane_point)::in,
io::di, io::uo) is det.
write_eps(Stream, Subject_pts, Clip_pts, Result_pts, !IO) :-
write_string(Stream, "%!PS-Adobe-3.0 EPSF-3.0\n", !IO),
write_string(Stream, "%%BoundingBox: 40 40 360 360\n", !IO),
write_string(Stream, "0 setlinewidth\n", !IO),
write_polygon(Stream, Clip_pts, ".5 0 0", "1 .7 .7", !IO),
write_polygon(Stream, Subject_pts, "0 .2 .5", ".4 .7 1", !IO),
write_string(Stream, "2 setlinewidth\n", !IO),
write_string(Stream, "[10 8] 0 setdash\n", !IO),
write_polygon(Stream, Result_pts, ".5 0 .5", ".7 .3 .8", !IO),
write_string(Stream, "%%EOF\n", !IO).
 
:- pred write_eps_to_file(string::in,
list(plane_point)::in,
list(plane_point)::in,
list(plane_point)::in,
io::di, io::uo) is det.
write_eps_to_file(Filename, Subject_pts, Clip_pts, Result_pts, !IO) :-
open_output(Filename, Open_result, !IO),
(if (Open_result = ok(Outp))
then write_eps(Outp, Subject_pts, Clip_pts, Result_pts, !IO)
else throw("Failed to open " ++ Filename ++ " for output.")).
 
main(!IO) :-
Subject_pts = [plane_point(50.0, 150.0),
plane_point(200.0, 50.0),
plane_point(350.0, 150.0),
plane_point(350.0, 300.0),
plane_point(250.0, 300.0),
plane_point(200.0, 250.0),
plane_point(150.0, 350.0),
plane_point(100.0, 250.0),
plane_point(100.0, 200.0)],
Clip_pts = [plane_point(100.0, 100.0),
plane_point(300.0, 100.0),
plane_point(300.0, 300.0),
plane_point(100.0, 300.0)],
Result_pts = clip(Subject_pts, Clip_pts),
write_plane_point_list(Result_pts, "\n", !IO), nl(!IO),
EPSF = "sutherland-hodgman.eps",
write_eps_to_file(EPSF, Subject_pts, Clip_pts, Result_pts, !IO),
write_string("Wrote " ++ EPSF, !IO), nl(!IO).
 
%%% local variables:
%%% mode: mercury
%%% prolog-indent-width: 2
%%% end:
</syntaxhighlight>
{{out}}
<pre>$ mmc sutherland_hodgman_task.m && ./sutherland_hodgman_task
(100.0, 116.66666666666669)
(124.99999999999999, 100.0)
(275.0, 100.0)
(300.0, 116.66666666666667)
(300.0, 300.0)
(250.0, 300.0)
(200.0, 250.0)
(175.0, 300.0)
(125.0, 300.0)
(100.0, 250.0)
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-mercury.png|alt=The polygons as generated by a Mercury program.]]
 
=={{header|Modula-2}}==
{{trans|ATS}}
{{works with|GNU Modula-2|13.0.0 20220926 (experimental)}}
<syntaxhighlight lang="modula2">
(* Sutherland-Hodgman polygon clipping, for ISO Modula-2. *)
 
MODULE Sutherland_Hodgman_Task;
 
IMPORT STextIO, SRealIO;
IMPORT TextIO, RealIO;
IMPORT IOChan, StreamFile;
 
TYPE PlanePoint =
RECORD
x : REAL;
y : REAL;
END;
 
PlaneEdge =
RECORD
pt0 : PlanePoint; (* The start point. *)
pt1 : PlanePoint; (* The end point. *)
END;
 
PROCEDURE evaluate_line (x1, y1, x2, y2, x : REAL) : REAL;
VAR dy, dx, slope, intercept : REAL;
BEGIN
dy := y2 - y1;
dx := x2 - x1;
slope := dy / dx;
intercept := ((dx * y1) - (dy * x1)) / dx;
RETURN (slope * x) + intercept
END evaluate_line;
 
PROCEDURE intersection_of_lines
(x1, y1, x2, y2, x3, y3, x4, y4 : REAL) : PlanePoint;
VAR intersection : PlanePoint;
denominator, xnumerator, ynumerator : REAL;
x1y2_y1x2, x3y4_y3x4 : REAL;
BEGIN
IF x1 = x2 THEN
intersection.x := x1;
intersection.y := evaluate_line (x3, y3, x4, y4, x1);
ELSIF x3 = x4 THEN
intersection.x := x3;
intersection.y := evaluate_line (x1, y1, x2, y2, x3);
ELSE
denominator := ((x1 - x2) * (y3 - y4)) - ((y1 - y2) * (x3 - x4));
x1y2_y1x2 := (x1 * y2) - (y1 * x2);
x3y4_y3x4 := (x3 * y4) - (y3 * x4);
xnumerator := (x1y2_y1x2 * (x3 - x4)) - ((x1 - x2) * x3y4_y3x4);
ynumerator := (x1y2_y1x2 * (y3 - y4)) - ((y1 - y2) * x3y4_y3x4);
intersection.x := xnumerator / denominator;
intersection.y := ynumerator / denominator;
END;
RETURN intersection;
END intersection_of_lines;
 
PROCEDURE intersection_of_edges
(e1, e2 : PlaneEdge) : PlanePoint;
BEGIN
RETURN intersection_of_lines (e1.pt0.x, e1.pt0.y,
e1.pt1.x, e1.pt1.y,
e2.pt0.x, e2.pt0.y,
e2.pt1.x, e2.pt1.y);
END intersection_of_edges;
 
PROCEDURE point_is_left_of_edge
(pt : PlanePoint;
edge : PlaneEdge) : BOOLEAN;
VAR x, y, x1, y1, x2, y2, op : REAL;
BEGIN
x := pt.x;
y := pt.y;
x1 := edge.pt0.x;
y1 := edge.pt0.y;
x2 := edge.pt1.x;
y2 := edge.pt1.y;
 
(* Outer product of the vectors (x1,y1)-->(x,y) and
(x1,y1)-->(x2,y2). *)
op := ((x - x1) * (y2 - y1)) - ((x2 - x1) * (y - y1));
 
RETURN (op < 0.0);
END point_is_left_of_edge;
 
PROCEDURE clip_subject_edge
(subject_edge : PlaneEdge;
clip_edge : PlaneEdge;
VAR n : CARDINAL;
VAR points : ARRAY OF PlanePoint);
VAR s1, s2 : PlanePoint;
s2_is_inside, s1_is_inside : BOOLEAN;
BEGIN
s1 := subject_edge.pt0;
s2 := subject_edge.pt1;
s2_is_inside := point_is_left_of_edge (s2, clip_edge);
s1_is_inside := point_is_left_of_edge (s1, clip_edge);
IF s2_is_inside THEN
IF s1_is_inside THEN
points[n] := s2;
n := n + 1;
ELSE
points[n] := intersection_of_edges (subject_edge, clip_edge);
n := n + 1;
points[n] := s2;
n := n + 1;
END;
ELSIF s1_is_inside THEN
points[n] := intersection_of_edges (subject_edge, clip_edge);
n := n + 1;
END;
END clip_subject_edge;
 
PROCEDURE for_each_subject_edge
(nsubject : CARDINAL;
subject_points : ARRAY OF PlanePoint;
clip_edge : PlaneEdge;
VAR n : CARDINAL;
VAR points : ARRAY OF PlanePoint);
VAR subject_edge : PlaneEdge;
i, j : CARDINAL;
BEGIN
n := 0;
FOR i := 0 TO nsubject - 1 DO
IF i = 0 THEN
j := nsubject - 1;
ELSE
j := i - 1;
END;
subject_edge.pt1 := subject_points[i];
subject_edge.pt0 := subject_points[j];
clip_subject_edge (subject_edge, clip_edge, n, points);
END;
END for_each_subject_edge;
 
PROCEDURE clip (VAR nsubject : CARDINAL;
VAR subject_points : ARRAY OF PlanePoint;
nclip : CARDINAL;
clip_points : ARRAY OF PlanePoint;
VAR workspace : ARRAY OF PlanePoint);
VAR clip_edge : PlaneEdge;
i, j, nwork : CARDINAL;
BEGIN
FOR i := 0 TO nclip - 1 DO
IF i = 0 THEN
j := nclip - 1;
ELSE
j := i - 1;
END;
clip_edge.pt1 := clip_points[i];
clip_edge.pt0 := clip_points[j];
for_each_subject_edge (nsubject, subject_points, clip_edge,
nwork, workspace);
FOR j := 0 TO nwork - 1 DO
subject_points[j] := workspace[j];
END;
nsubject := nwork;
END;
END clip;
 
PROCEDURE set_point
(VAR points : ARRAY OF PlanePoint;
i : CARDINAL;
x, y : REAL);
BEGIN
points[i].x := x;
points[i].y := y;
END set_point;
 
PROCEDURE write_polygon
(cid : IOChan.ChanId;
npoly : CARDINAL;
polygon : ARRAY OF PlanePoint;
line_color : ARRAY OF CHAR;
fill_color : ARRAY OF CHAR);
VAR i : CARDINAL;
BEGIN
RealIO.WriteReal (cid, polygon[0].x, 10);
TextIO.WriteString (cid, ' ');
RealIO.WriteReal (cid, polygon[0].y, 10);
TextIO.WriteString (cid, ' moveto');
TextIO.WriteLn (cid);
FOR i := 1 TO npoly - 1 DO
RealIO.WriteReal (cid, polygon[i].x, 10);
TextIO.WriteString (cid, ' ');
RealIO.WriteReal (cid, polygon[i].y, 10);
TextIO.WriteString (cid, ' lineto');
TextIO.WriteLn (cid);
END;
TextIO.WriteString (cid, 'closepath');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, line_color);
TextIO.WriteString (cid, ' setrgbcolor');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, 'gsave');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, fill_color);
TextIO.WriteString (cid, ' setrgbcolor');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, 'fill');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, 'grestore');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, 'stroke');
TextIO.WriteLn (cid);
END write_polygon;
 
PROCEDURE write_eps
(cid : IOChan.ChanId;
nsubject : CARDINAL;
subject_polygon : ARRAY OF PlanePoint;
nclip : CARDINAL;
clip_polygon : ARRAY OF PlanePoint;
nresult : CARDINAL;
result_polygon : ARRAY OF PlanePoint);
BEGIN
TextIO.WriteString (cid, '%!PS-Adobe-3.0 EPSF-3.0');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, '%%BoundingBox: 40 40 360 360');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, '0 setlinewidth');
TextIO.WriteLn (cid);
write_polygon (cid, nclip, clip_polygon,
'.5 0 0', '1 .7 .7');
write_polygon (cid, nsubject, subject_polygon,
'0 .2 .5', '.4 .7 1');
TextIO.WriteString (cid, '2 setlinewidth');
TextIO.WriteLn (cid);
TextIO.WriteString (cid, '[10 8] 0 setdash');
TextIO.WriteLn (cid);
write_polygon (cid, nresult, result_polygon,
'.5 0 .5', '.7 .3 .8');
TextIO.WriteString (cid, '%%EOF');
TextIO.WriteLn (cid);
END write_eps;
 
PROCEDURE write_eps_to_file
(filename : ARRAY OF CHAR;
nsubject : CARDINAL;
subject_polygon : ARRAY OF PlanePoint;
nclip : CARDINAL;
clip_polygon : ARRAY OF PlanePoint;
nresult : CARDINAL;
result_polygon : ARRAY OF PlanePoint);
VAR cid : IOChan.ChanId;
open_results : StreamFile.OpenResults;
BEGIN
StreamFile.Open (cid, filename,
StreamFile.write,
open_results);
write_eps (cid,
nsubject, subject_polygon,
nclip, clip_polygon,
nresult, result_polygon);
StreamFile.Close (cid);
END write_eps_to_file;
 
CONST NMax = 100;
 
VAR subject_polygon : ARRAY [0 .. NMax - 1] OF PlanePoint;
clip_polygon : ARRAY [0 .. NMax - 1] OF PlanePoint;
workspace : ARRAY [0 .. NMax - 1] OF PlanePoint;
result_polygon : ARRAY [0 .. NMax - 1] OF PlanePoint;
nsubject, nclip, nresult, i : CARDINAL;
 
BEGIN
nsubject := 9;
set_point (subject_polygon, 0, 50.0, 150.0);
set_point (subject_polygon, 1, 200.0, 50.0);
set_point (subject_polygon, 2, 350.0, 150.0);
set_point (subject_polygon, 3, 350.0, 300.0);
set_point (subject_polygon, 4, 250.0, 300.0);
set_point (subject_polygon, 5, 200.0, 250.0);
set_point (subject_polygon, 6, 150.0, 350.0);
set_point (subject_polygon, 7, 100.0, 250.0);
set_point (subject_polygon, 8, 100.0, 200.0);
 
nclip := 4;
set_point (clip_polygon, 0, 100.0, 100.0);
set_point (clip_polygon, 1, 300.0, 100.0);
set_point (clip_polygon, 2, 300.0, 300.0);
set_point (clip_polygon, 3, 100.0, 300.0);
 
FOR i := 0 TO nsubject - 1 DO
result_polygon[i] := subject_polygon[i];
END;
nresult := nsubject;
 
clip (nresult, result_polygon, nclip, clip_polygon,
workspace);
 
FOR i := 0 TO nsubject - 1 DO
STextIO.WriteString ('(');
SRealIO.WriteReal (result_polygon[i].x, 8);
STextIO.WriteString (', ');
SRealIO.WriteReal (result_polygon[i].y, 8);
STextIO.WriteString (')');
STextIO.WriteLn;
END;
 
write_eps_to_file ('sutherland-hodgman.eps',
nsubject, subject_polygon,
nclip, clip_polygon,
nresult, result_polygon);
STextIO.WriteString ('Wrote sutherland-hodgman.eps');
STextIO.WriteLn;
END Sutherland_Hodgman_Task.
</syntaxhighlight>
{{out}}
<pre>gm2 sutherland_hodgman_task.mod && ./a.out
(100.0000, 116.6667)
(125.0000, 100.0000)
(275.0000, 100.0000)
(300.0000, 116.6667)
(300.0000, 300.0000)
(250.0000, 300.0000)
(200.0000, 250.0000)
(175.0000, 300.0000)
(125.0000, 300.0000)
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-mod2.png|alt=Sutherland-Hodgman task polygons from Modula-2.]]
 
=={{header|Nim}}==
Line 3,853 ⟶ 4,762:
 
Also see output image: [https://github.com/thundergnat/rc/blob/master/img/Sutherland-Hodgman-polygon-clipping-perl6.svg offsite SVG image]
 
=={{header|RATFOR}}==
{{trans|ATS}}
{{works with|ratfor77|[https://sourceforge.net/p/chemoelectric/ratfor77/ public domain 1.0]}}
<syntaxhighlight lang="ratfor">
# Sutherland-Hodgman polygon clipping.
#
# On a POSIX platform, the program can be compiled with f2c and run
# somewhat as follows:
#
# ratfor77 sutherland-hodgman.r > sutherland-hodgman.f
# f2c -C sutherland-hodgman.f
# cc sutherland-hodgman.c -lf2c
# ./a.out
#
# With gfortran, a little differently:
#
# ratfor77 sutherland-hodgman.r > sutherland-hodgman.f
# gfortran -fcheck=all -std=legacy sutherland-hodgman.f
# ./a.out
 
function evalln (x1, y1, x2, y2, x)
#
# Given the line (x1,y1)--(x2,y2), evaluate it at x.
#
implicit none
real evalln
real x1, y1, x2, y2, x
real dy, dx, slope, xcept
dy = y2 - y1
dx = x2 - x1
slope = dy / dx
xcept = ((dx * y1) - (dy * x1)) / dx
evalln = (slope * x) + xcept
end
 
subroutine xsctln (x1, y1, x2, y2, x3, y3, x4, y4, x, y)
#
# Given lines (x1,y1)--(x2,y2) and (x3,y3)--(x4,y4), find their
# intersection (x,y).
#
implicit none
real x1, y1, x2, y2, x3, y3, x4, y4, x, y
real evalln
real denom, xnumer, ynumer, xyyx12, xyyx34
if (x1 == x2)
{
x = x1
y = evalln (x3, y3, x4, y4, x1)
}
else if (x3 == x4)
{
x = x3
y = evalln (x1, y1, x2, y2, x3)
}
else
{
denom = ((x1 - x2) * (y3 - y4)) - ((y1 - y2) * (x3 - x4))
xyyx12 = (x1 * y2) - (y1 * x2)
xyyx34 = (x3 * y4) - (y3 * x4)
xnumer = (xyyx12 * (x3 - x4)) - ((x1 - x2) * xyyx34)
ynumer = (xyyx12 * (y3 - y4)) - ((y1 - y2) * xyyx34)
x = xnumer / denom
y = ynumer / denom
}
end
 
function ptleft (x, y, x1, y1, x2, y2)
#
# Is the point (x,y) left of the edge (x1,y1)--(x2,y2)?
#
implicit none
logical ptleft
real x, y, x1, y1, x2, y2
ptleft = (((x - x1) * (y2 - y1)) - ((x2 - x1) * (y - y1)) < 0)
end
 
subroutine clpsbe (xs1, ys1, xs2, ys2, xc1, yc1, xc2, yc2, n, pts)
#
# Clip subject edge (xs1,ys1)--(xs2,ys2) with clip edge
# (xc1,yc1)--(xc2,yc2).
#
implicit none
real xs1, ys1, xs2, ys2, xc1, yc1, xc2, yc2
integer n
real pts(2,*), x, y
logical ptleft, s2left, s1left
s2left = ptleft (xs2, ys2, xc1, yc1, xc2, yc2)
s1left = ptleft (xs1, ys1, xc1, yc1, xc2, yc2)
if (s2left)
{
if (s1left)
{
n = n + 1
pts(1,n) = xs2
pts(2,n) = ys2
}
else
{
call xsctln (xs1, ys1, xs2, ys2, xc1, yc1, xc2, yc2, x, y)
n = n + 1
pts(1,n) = x
pts(2,n) = y
n = n + 1
pts(1,n) = xs2
pts(2,n) = ys2
}
}
else if (s1left)
{
call xsctln (xs1, ys1, xs2, ys2, xc1, yc1, xc2, yc2, x, y)
n = n + 1
pts(1,n) = x
pts(2,n) = y
}
end
 
subroutine sublp (nsub, ptssub, xc1, yc1, xc2, yc2, n, pts)
#
# Loop over the subject points in ptssub, clipping the edges
# therein. Produce a result in pts.
#
implicit none
integer nsub, n
real ptssub(2,*), pts(2,*)
real xc1, yc1, xc2, yc2
real xs1, ys1, xs2, ys2
integer i, j
for (i = 1; i <= nsub; i = i + 1)
{
xs2 = ptssub(1,i)
ys2 = ptssub(2,i)
j = i - 1
if (j == 0) j = nsub
xs1 = ptssub(1,j)
ys1 = ptssub(2,j)
call clpsbe (xs1, ys1, xs2, ys2, xc1, yc1, xc2, yc2, n, pts)
}
end
 
subroutine clip (nsub, ptssub, nclp, ptsclp, ptswrk)
#
# Loop over the clip points in ptsclp, clipping the subject stored
# in ptssub. Use ptswrk as workspace.
#
implicit none
integer nsub, nclp
real ptssub(2,*), ptsclp(2,*), ptswrk(2,*)
integer i, j, nwrk
real xc1, yc1, xc2, yc2
for (i = 1; i <= nclp; i = i + 1)
{
xc2 = ptsclp(1,i)
yc2 = ptsclp(2,i)
j = i - 1
if (j == 0) j = nclp
xc1 = ptsclp(1,j)
yc1 = ptsclp(2,j)
nwrk = 0
call sublp (nsub, ptssub, xc1, yc1, xc2, yc2, nwrk, ptswrk)
 
# Copy the new subject over the old subject.
for (j = 1; j <= nwrk; j = j + 1)
{
ptssub(1,j) = ptswrk(1,j)
ptssub(2,j) = ptswrk(2,j)
}
nsub = nwrk
}
end
 
subroutine wrtpts (eps, n, pts, linclr, filclr)
#
# Write a polygon as PostScript code.
#
implicit none
character*10 linclr, filclr
integer eps, n, i
real pts(2,*)
 
10 format (F12.6, ' ', F12.6, ' moveto')
20 format (F12.6, ' ', F12.6, ' lineto')
30 format ('closepath')
40 format ('gsave')
50 format ('grestore')
60 format ('fill')
70 format ('stroke')
80 format (A10, ' setrgbcolor')
 
write (eps, 10) pts(1,1), pts(2,1)
for (i = 2; i <= n; i = i + 1)
write (eps, 20) pts(1,i), pts(2,i)
write (eps, 30)
write (eps, 80) linclr
write (eps, 40)
write (eps, 80) filclr
write (eps, 60)
write (eps, 50)
write (eps, 70)
end
 
subroutine wrteps (eps, nsub, ptssub, nclp, ptsclp, nres, ptsres)
#
# Write an Encapsulated PostScript file.
#
implicit none
integer eps
integer nsub, nclp, nres
real ptssub(2,*), ptsclp(2,*), ptsres(2,*)
 
10 format ('%!PS-Adobe-3.0 EPSF-3.0')
20 format ('%%BoundingBox: 40 40 360 360')
30 format ('0 setlinewidth ')
40 format ('2 setlinewidth')
50 format ('[10 8] 0 setdash')
60 format ('%%EOF')
 
write (eps, 10)
write (eps, 20)
write (eps, 30)
call wrtpts (eps, nclp, ptsclp, '.5 0 0 ', '1 .7 .7 ')
call wrtpts (eps, nsub, ptssub, '0 .2 .5 ', '.4 .7 1 ')
write (eps, 40)
write (eps, 50)
call wrtpts (eps, nres, ptsres, '.5 0 .5 ', '.7 .3 .8 ')
write (eps, 60)
end
 
define(NMAX,100) # Maximum number of points in a polygon.
define(EPSF,9) # Unit number for the EPS file.
 
program shclip
implicit none
integer nsub, nclp, nres
real ptssub(2,NMAX), ptsclp(2,NMAX), ptsres(2,NMAX), ptswrk(2,NMAX)
integer i
integer eps
 
nsub = 9
ptssub(1,1) = 50; ptssub(2,1) = 150
ptssub(1,2) = 200; ptssub(2,2) = 50
ptssub(1,3) = 350; ptssub(2,3) = 150
ptssub(1,4) = 350; ptssub(2,4) = 300
ptssub(1,5) = 250; ptssub(2,5) = 300
ptssub(1,6) = 200; ptssub(2,6) = 250
ptssub(1,7) = 150; ptssub(2,7) = 350
ptssub(1,8) = 100; ptssub(2,8) = 250
ptssub(1,9) = 100; ptssub(2,9) = 200
 
nclp = 4
ptsclp(1,1) = 100; ptsclp(2,1) = 100
ptsclp(1,2) = 300; ptsclp(2,2) = 100
ptsclp(1,3) = 300; ptsclp(2,3) = 300
ptsclp(1,4) = 100; ptsclp(2,4) = 300
 
# Copy the subject points to the "result" array.
for (i = 1; i <= nsub; i = i + 1)
{
ptsres(1,i) = ptssub(1,i)
ptsres(2,i) = ptssub(2,i)
}
nres = nsub
 
call clip (nres, ptsres, nclp, ptsclp, ptswrk)
for (i = 1; i <= nres; i = i + 1)
write (*, 1000) ptsres(1,i), ptsres(2,i)
1000 format ('(', F8.4, ', ', F8.4, ')')
 
eps = EPSF
open (unit=eps, file='sutherland-hodgman.eps')
call wrteps (eps, nsub, ptssub, nclp, ptsclp, nres, ptsres)
write (*, 1010)
1010 format ('Wrote sutherland-hodgman.eps')
end
</syntaxhighlight>
{{out}}
<pre>(100.0000, 116.6667)
(125.0000, 100.0000)
(275.0000, 100.0000)
(300.0000, 116.6667)
(300.0000, 300.0000)
(250.0000, 300.0000)
(200.0000, 250.0000)
(175.0000, 300.0000)
(125.0000, 300.0000)
(100.0000, 250.0000)
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-ratfor.png|alt=The polygons as generated by Ratfor.]]
 
=={{header|Ruby}}==
Line 4,302 ⟶ 5,499:
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-scheme.png|alt=The polygons of the task]]
 
=={{header|TypeScript}}==
<syntaxhighlight lang="typescript">interface XYCoords {
x : number;
y : number;
}
 
const inside = ( cp1 : XYCoords, cp2 : XYCoords, p : XYCoords) : boolean => {
return (cp2.x-cp1.x)*(p.y-cp1.y) > (cp2.y-cp1.y)*(p.x-cp1.x);
};
 
const intersection = ( cp1 : XYCoords ,cp2 : XYCoords ,s : XYCoords, e : XYCoords ) : XYCoords => {
const dc = {
x: cp1.x - cp2.x,
y : cp1.y - cp2.y
},
dp = { x: s.x - e.x,
y : s.y - e.y
},
n1 = cp1.x * cp2.y - cp1.y * cp2.x,
n2 = s.x * e.y - s.y * e.x,
n3 = 1.0 / (dc.x * dp.y - dc.y * dp.x);
return { x : (n1*dp.x - n2*dc.x) * n3,
y : (n1*dp.y - n2*dc.y) * n3
};
};
 
export const sutherland_hodgman = ( subjectPolygon : Array<XYCoords>,
clipPolygon : Array<XYCoords> ) : Array<XYCoords> => {
let cp1 : XYCoords = clipPolygon[clipPolygon.length-1];
let cp2 : XYCoords;
let s : XYCoords;
let e : XYCoords;
let outputList : Array<XYCoords> = subjectPolygon;
for( var j in clipPolygon ) {
cp2 = clipPolygon[j];
var inputList = outputList;
outputList = [];
s = inputList[inputList.length - 1]; // last on the input list
for (var i in inputList) {
e = inputList[i];
if (inside(cp1,cp2,e)) {
if (!inside(cp1,cp2,s)) {
outputList.push(intersection(cp1,cp2,s,e));
}
outputList.push(e);
}
else if (inside(cp1,cp2,s)) {
outputList.push(intersection(cp1,cp2,s,e));
}
s = e;
}
cp1 = cp2;
}
return outputList
}</syntaxhighlight>
 
=={{header|Sidef}}==
Line 4,430 ⟶ 5,568:
(100.00, 250.00)
</pre>
 
=={{header|Standard ML}}==
{{trans|ATS}}
{{works with|MLton|20210117}}
 
<syntaxhighlight lang="sml">
(* Sutherland-Hodgman polygon clipping. *)
 
fun evaluate_line (x1 : real, y1 : real,
x2 : real, y2 : real,
x : real) =
let
val dy = y2 - y1
and dx = x2 - x1
val slope = dy / dx
and intercept = ((dx * y1) - (dy * x1)) / dx
in
(slope * x) + intercept
end
 
fun intersection_of_lines (x1 : real, y1 : real,
x2 : real, y2 : real,
x3 : real, y3 : real,
x4 : real, y4 : real) =
if Real.== (x1, x2) then
(x1, evaluate_line (x3, y3, x4, y4, x1))
else if Real.== (x3, x4) then
(x3, evaluate_line (x1, y1, x2, y2, x3))
else
let
val denominator =
((x1 - x2) * (y3 - y4)) - ((y1 - y2) * (x3 - x4))
and x1y2_y1x2 = (x1 * y2) - (y1 * x2)
and x3y4_y3x4 = (x3 * y4) - (y3 * x4)
 
val xnumerator =
(x1y2_y1x2 * (x3 - x4)) - ((x1 - x2) * x3y4_y3x4)
and ynumerator =
(x1y2_y1x2 * (y3 - y4)) - ((y1 - y2) * x3y4_y3x4)
in
(xnumerator / denominator,
ynumerator / denominator)
end
 
fun intersection_of_edges (((x1, y1), (x2, y2)),
((x3, y3), (x4, y4))) =
intersection_of_lines (x1, y1, x2, y2, x3, y3, x4, y4)
 
fun point_is_left_of_edge ((x, y), ((x1, y1), (x2, y2))) =
(* Outer product of the vectors (x1,y1)-->(x,y) and
(x1,y1)-->(x2,y2). *)
((x - x1) * (y2 - y1)) - ((x2 - x1) * (y - y1)) < 0.0
 
fun clip_subject_edge (subject_edge, clip_edge, accum) =
let
fun intersection () =
intersection_of_edges (subject_edge, clip_edge)
 
val (s1, s2) = subject_edge
val s2_is_inside = point_is_left_of_edge (s2, clip_edge)
and s1_is_inside = point_is_left_of_edge (s1, clip_edge)
in
case (s2_is_inside, s1_is_inside) of
(true, true) => s2 :: accum
| (true, false) => s2 :: intersection () :: accum
| (false, true) => intersection () :: accum
| (false, false) => accum
end
 
fun for_each_subject_edge (i, subject_points, clip_edge, accum) =
let
val n = Array.length subject_points
in
if i = n then
Array.fromList (rev accum)
else
let
val s2 = Array.sub (subject_points, i)
and s1 = (if i = 0 then
Array.sub (subject_points, n - 1)
else
Array.sub (subject_points, i - 1))
val accum = clip_subject_edge ((s1, s2), clip_edge, accum)
in
for_each_subject_edge (i + 1, subject_points, clip_edge,
accum)
end
end
 
fun for_each_clip_edge (i, subject_points, clip_points) =
let
val n = Array.length clip_points
in
if i = n then
subject_points
else
let
val c2 = Array.sub (clip_points, i)
and c1 = (if i = 0 then
Array.sub (clip_points, n - 1)
else
Array.sub (clip_points, i - 1))
val subject_points =
for_each_subject_edge (0, subject_points, (c1, c2), [])
in
for_each_clip_edge (i + 1, subject_points, clip_points)
end
end
 
fun clip (subject_points, clip_points) =
for_each_clip_edge (0, subject_points, clip_points)
 
fun write_eps (outf, subject_points, clip_points, result_points) =
(* The EPS code that will be generated is based on that which is
generated by the C implementation of this task. *)
let
fun moveto (x, y) =
(TextIO.output (outf, Real.toString x);
TextIO.output (outf, " ");
TextIO.output (outf, Real.toString y);
TextIO.output (outf, " moveto\n"))
fun lineto (x, y) =
(TextIO.output (outf, Real.toString x);
TextIO.output (outf, " ");
TextIO.output (outf, Real.toString y);
TextIO.output (outf, " lineto\n"))
fun setrgbcolor rgb =
(TextIO.output (outf, rgb);
TextIO.output (outf, " setrgbcolor\n"))
fun closepath () = TextIO.output (outf, "closepath\n")
fun fill () = TextIO.output (outf, "fill\n")
fun stroke () = TextIO.output (outf, "stroke\n")
fun gsave () = TextIO.output (outf, "gsave\n")
fun grestore () = TextIO.output (outf, "grestore\n")
fun showpoly (poly, line_color, fill_color) =
let
val n = Array.length poly
in
moveto (Array.sub (poly, 0));
Array.app lineto poly;
closepath ();
setrgbcolor line_color;
gsave ();
setrgbcolor fill_color;
fill ();
grestore ();
stroke ()
end
in
TextIO.output (outf, "%!PS-Adobe-3.0 EPSF-3.0\n");
TextIO.output (outf, "%%BoundingBox: 40 40 360 360\n");
TextIO.output (outf, "0 setlinewidth\n");
showpoly (clip_points, ".5 0 0", "1 .7 .7");
showpoly (subject_points, "0 .2 .5", ".4 .7 1");
TextIO.output (outf, "2 setlinewidth\n");
TextIO.output (outf, "[10 8] 0 setdash\n");
showpoly (result_points, ".5 0 .5", ".7 .3 .8");
TextIO.output (outf, "%%EOF\n")
end
 
fun write_eps_to_file (outfile, subject_points, clip_points,
result_points) =
let
val outf = TextIO.openOut outfile
in
write_eps (outf, subject_points, clip_points, result_points);
TextIO.closeOut outf
end
 
val subject_points =
Array.fromList
[(50.0, 150.0),
(200.0, 50.0),
(350.0, 150.0),
(350.0, 300.0),
(250.0, 300.0),
(200.0, 250.0),
(150.0, 350.0),
(100.0, 250.0),
(100.0, 200.0)]
 
val clip_points =
Array.fromList
[(100.0, 100.0),
(300.0, 100.0),
(300.0, 300.0),
(100.0, 300.0)]
 
val result_points = clip (subject_points, clip_points)
 
fun print_point (x, y) =
(TextIO.print " (";
TextIO.print (Real.toString x);
TextIO.print " ";
TextIO.print (Real.toString y);
TextIO.print ")")
;
 
Array.app print_point result_points;
TextIO.print "\n";
write_eps_to_file ("sutherland-hodgman.eps",
subject_points, clip_points, result_points);
TextIO.print "Wrote sutherland-hodgman.eps\n";
 
(*
local variables:
mode: SML
sml-indent-level: 2
end:
*)
</syntaxhighlight>
 
{{out}}
<pre>$ mlton sutherland-hodgman.sml && ./sutherland-hodgman
(100 116.666666667) (125 100) (275 100) (300 116.666666667) (300 300) (250 300) (200 250) (175 300) (125 300) (100 250)
Wrote sutherland-hodgman.eps</pre>
[[File:Sutherland-hodgman-from-sml.png|alt=The polygons of the task.]]
 
=={{header|Swift}}==
Line 4,664 ⟶ 6,019:
</pre>
[[File:Sutherland-Hodgman.gif]]
 
=={{header|TypeScript}}==
<syntaxhighlight lang="typescript">interface XYCoords {
x : number;
y : number;
}
 
const inside = ( cp1 : XYCoords, cp2 : XYCoords, p : XYCoords) : boolean => {
return (cp2.x-cp1.x)*(p.y-cp1.y) > (cp2.y-cp1.y)*(p.x-cp1.x);
};
 
const intersection = ( cp1 : XYCoords ,cp2 : XYCoords ,s : XYCoords, e : XYCoords ) : XYCoords => {
const dc = {
x: cp1.x - cp2.x,
y : cp1.y - cp2.y
},
dp = { x: s.x - e.x,
y : s.y - e.y
},
n1 = cp1.x * cp2.y - cp1.y * cp2.x,
n2 = s.x * e.y - s.y * e.x,
n3 = 1.0 / (dc.x * dp.y - dc.y * dp.x);
return { x : (n1*dp.x - n2*dc.x) * n3,
y : (n1*dp.y - n2*dc.y) * n3
};
};
 
export const sutherland_hodgman = ( subjectPolygon : Array<XYCoords>,
clipPolygon : Array<XYCoords> ) : Array<XYCoords> => {
let cp1 : XYCoords = clipPolygon[clipPolygon.length-1];
let cp2 : XYCoords;
let s : XYCoords;
let e : XYCoords;
let outputList : Array<XYCoords> = subjectPolygon;
for( var j in clipPolygon ) {
cp2 = clipPolygon[j];
var inputList = outputList;
outputList = [];
s = inputList[inputList.length - 1]; // last on the input list
for (var i in inputList) {
e = inputList[i];
if (inside(cp1,cp2,e)) {
if (!inside(cp1,cp2,s)) {
outputList.push(intersection(cp1,cp2,s,e));
}
outputList.push(e);
}
else if (inside(cp1,cp2,s)) {
outputList.push(intersection(cp1,cp2,s,e));
}
s = e;
}
cp1 = cp2;
}
return outputList
}</syntaxhighlight>
 
 
=={{header|Wren}}==
{{libheader|DOME}}
{{libheader|Wren-polygon}}
<syntaxhighlight lang="ecmascriptwren">import "graphics" for Canvas, Color
import "dome" for Window
import "./polygon" for Polygon
PureFox
9,476

edits

Retrieved from "https://rosettacode.org/wiki/Special:MobileDiff/333574...350092"