Anonymous user
Frobenius numbers: Difference between revisions
m
→{{header|REXX}}: added the computer programming language REXX.
m (→{{header|REXX}}: added a REXX stub.) |
m (→{{header|REXX}}: added the computer programming language REXX.) |
||
Line 6:
<br><br>
=={{header|REXX}}==
<lang rexx>/*REXX program finds Frobenius numbers where the numbers are less than some number N. */
parse arg hi cols . /*obtain optional argument from the CL.*/
if hi=='' | hi=="," then hi= 10000 /* " " " " " " */
if cols=='' | cols=="," then cols= 10 /* " " " " " " */
call genP /*build array of semaphores for primes.*/
w= 10 /*width of a number in any column. */
@Frob= ' Frobenius numbers that are < ' commas(hi)
if cols>0 then say ' index │'center(@Frob, 1 + cols*(w+1) )
if cols>0 then say '───────┼'center("" , 1 + cols*(w+1), '─')
idx= 1 /*initialize the index of output lines.*/
$= /*a list of Frobenius numbers (so far)*/
do j=1; jp= j + 1 /*generate Frobenius numbers < HI */
y= @.j * @.jp - @.j - @.jp
if y>= hi then leave
if cols==0 then iterate /*Build the list (to be shown later)? */
c= commas(y) /*maybe add commas to the number. */
$= $ right(c, max(w, length(c) ) ) /*add a Frobenius #──►list, allow big #*/
if j//cols\==0 then iterate /*have we populated a line of output? */
say center(idx, 7)'│' substr($, 2); $= /*display what we have so far (cols). */
idx= idx + cols /*bump the index count for the output*/
end /*j*/
if $\=='' then say center(idx, 7)"│" substr($, 2) /*possible display residual output.*/
say
say 'Found ' commas(j-1) @FROB
exit 0 /*stick a fork in it, we're all done. */
/*──────────────────────────────────────────────────────────────────────────────────────*/
commas: parse arg ?; do jc=length(?)-3 to 1 by -3; ?=insert(',', ?, jc); end; return ?
/*──────────────────────────────────────────────────────────────────────────────────────*/
genP: @.1=2; @.2=3; @.3=5; @.4=7; @.5=11 /*define some low primes. */
#=5; s.#= @.# **2 /*number of primes so far; prime². */
/* [↓] generate more primes ≤ high.*/
do j=@.#+2 by 2 to hi /*find odd primes from here on. */
parse var j '' -1 _; if _==5 then iterate /*J divisible by 5? (right dig)*/
if j// 3==0 then iterate /*" " " 3? */
if j// 7==0 then iterate /*" " " 7? */
/* [↑] the above five lines saves time*/
do k=5 while s.k<=j /* [↓] divide by the known odd primes.*/
if j // @.k == 0 then iterate j /*Is J ÷ X? Then not prime. ___ */
end /*k*/ /* [↑] only process numbers ≤ √ J */
#= #+1; @.#= j; s.#= j*j /*bump # Ps; assign next P; P squared*/
end /*j*/; return</lang>
{{out|output|text= when using the default inputs:}}
<pre>
index │ Frobenius numbers that are < 10,000
───────┼───────────────────────────────────────────────────────────────────────────────────────────────────────────────
1 │ 1 7 23 59 119 191 287 395 615 839
11 │ 1,079 1,439 1,679 1,931 2,391 3,015 3,479 3,959 4,619 5,039
21 │ 5,615 6,395 7,215 8,447 9,599
Found 25 Frobenius numbers that are < 10,000
</pre>
=={{header|Ring}}==
| |||