Ruth-Aaron numbers: Difference between revisions

</pre>

=={{header|Factor}}==

{{works with|Factor|0.99 2022-04-03}}

<lang factor>USING: assocs.extras grouping io kernel lists lists.lazy math

math.primes.factors prettyprint ranges sequences ;

: pair-same? ( ... n quot: ( ... m -- ... n ) -- ... ? )

[ dup 1 + ] dip same? ; inline

: RA-f? ( n -- ? ) [ factors sum ] pair-same? ;

: RA-d? ( n -- ? ) [ group-factors sum-keys ] pair-same? ;

: filter-naturals ( quot -- list ) 1 lfrom swap lfilter ; inline

: RA-f ( -- list ) [ RA-f? ] filter-naturals ;

: RA-d ( -- list ) [ RA-d? ] filter-naturals ;

: list. ( list -- )

30 swap ltake list>array 10 group simple-table. ;

"First 30 Ruth-Aaron numbers (factors):" print

RA-f list. nl

"First 30 Ruth-Aaron numbers (divisors):" print

RA-d list.</lang>

{{out}}

<pre>

First 30 Ruth-Aaron numbers (factors):

5 8 15 77 125 714 948 1330 1520 1862

2491 3248 4185 4191 5405 5560 5959 6867 8280 8463

10647 12351 14587 16932 17080 18490 20450 24895 26642 26649

First 30 Ruth-Aaron numbers (divisors):

5 24 49 77 104 153 369 492 714 1682

2107 2299 2600 2783 5405 6556 6811 8855 9800 12726

13775 18655 21183 24024 24432 24880 25839 26642 35456 40081