Sorting algorithms/Selection sort: Difference between revisions

=={{header|Action!}}==

<lang Action!>PROC PrintArray(INT ARRAY a INT size)

INT i

Put('[)

FOR i=0 TO size-1

DO

IF i>0 THEN Put(' ) FI

PrintI(a(i))

OD

Put(']) PutE()

RETURN

PROC SelectionSort(INT ARRAY a INT size)

INT i,j,minpos,tmp

FOR i=0 TO size-2

DO

minpos=i

FOR j=i+1 TO size-1

DO

IF a(minpos)>a(j) THEN

minpos=j

FI

OD

IF minpos#i THEN

tmp=a(i)

a(i)=a(minpos)

a(minpos)=tmp

FI

OD

RETURN

PROC Test(INT ARRAY a INT size)

PrintE("Array before sort:")

PrintArray(a,size)

SelectionSort(a,size)

PrintE("Array after sort:")

PrintArray(a,size)

PutE()

RETURN

PROC Main()

INT ARRAY

a(10)=[1 4 65535 0 3 7 4 8 20 65530],

b(21)=[10 9 8 7 6 5 4 3 2 1 0

65535 65534 65533 65532 65531

65530 65529 65528 65527 65526],

c(8)=[101 102 103 104 105 106 107 108],

d(12)=[1 65535 1 65535 1 65535 1

65535 1 65535 1 65535]

Test(a,10)

Test(b,21)

Test(c,8)

Test(d,12)

RETURN</lang>

{{out}}

[https://gitlab.com/amarok8bit/action-rosetta-code/-/raw/master/images/Selection_sort.png Screenshot from Atari 8-bit computer]

<pre>

Array before sort:

[1 4 -1 0 3 7 4 8 20 -6]

Array after sort:

[-6 -1 0 1 3 4 4 7 8 20]

Array before sort:

[10 9 8 7 6 5 4 3 2 1 0 -1 -2 -3 -4 -5 -6 -7 -8 -9 -10]

Array after sort:

[-10 -9 -8 -7 -6 -5 -4 -3 -2 -1 0 1 2 3 4 5 6 7 8 9 10]

Array before sort:

[101 102 103 104 105 106 107 108]

Array after sort:

[101 102 103 104 105 106 107 108]

Array before sort:

[1 -1 1 -1 1 -1 1 -1 1 -1 1 -1]

Array after sort:

[-1 -1 -1 -1 -1 -1 1 1 1 1 1 1]

</pre>