RPG attributes generator: Difference between revisions
→{{header|Atari BASIC}}: Add implementation.
(→{{header|Atari BASIC}}: Add implementation.) |
|||
Line 907:
print ["values:" vals ]
print ["with sum:" sum vals]</lang>
=={{header|Atari BASIC}}==
{{trans|Commodore BASIC}}
<lang basic>100 REM RPG character generator
110 DIM AT(5)
120 DIM AT$(18)
130 AT$="StrDexConIntWisCha"
140 PT=0:SA=0
150 PRINT CHR$(125);CHR$(29);CHR$(31);"Rolling..."
160 FOR AI=0 TO 5
170 DT=0:MI=6:REM dice total, min die
180 FOR I=0 TO 3
190 D=INT(RND(1)*6)+1
200 DT=DT+D
210 IF D<MI THEN MI=D
220 NEXT I
230 DT=DT-MI
240 AT(AI)=DT
250 PT=PT+DT
260 IF DT>=15 THEN SA=SA+1
270 NEXT AI
280 IF PT<75 OR SA<2 THEN 140
290 PRINT CHR$(125);"Character Attributes:"
300 PRINT
310 FOR AI=0 TO 5
315 POSITION 10,AI+2
320 PRINT AT$(AI*3+1,AI*3+3);":";
330 POSITION 16-INT(AT(AI)/10),AI+2
340 PRINT AT(AI)
350 NEXT AI
360 POSITION 8,9
370 PRINT "Total: ";PT
380 PRINT
390 PRINT "Do you accept? ";
400 OPEN #1,4,0,"K:"
410 GET #1,K
420 IF K<>78 AND K<>89 THEN 410
430 PRINT CHR$(K)
440 CLOSE #1
450 IF K=78 THEN 140
460 POSITION 0,13
470 PRINT "Excellent. Good luck on your adventure!"</lang>
{{Out}}
<pre> Character Attributes:
Str: 17
Dex: 15
Con: 13
Int: 11
Wis: 11
Cha: 14
Total: 81
Do you accept? Y
Excellent. Good luck on your adventure!
Ready
</pre>
=={{header|C}}==
| |||