Perlin noise: Difference between revisions
Added Algol 68
(Added Algol 68) |
|||
| (3 intermediate revisions by 3 users not shown) | |||
Line 72:
<pre>
0.13691995878400011
</pre>
=={{header|ALGOL 68}}==
{{Trans|11l}}
<syntaxhighlight lang="algol68">
BEGIN # perlin noise - translated from the 11l sample #
[ 0 : 511 ]INT p;
p[ 256 : ] := (151,160,137,91,90,15
,131,13,201,95,96,53,194,233,7,225,140,36,103,30,69,142,8,99,37,240,21,10,23
,190, 6,148,247,120,234,75,0,26,197,62,94,252,219,203,117,35,11,32,57,177,33
,88,237,149,56,87,174,20,125,136,171,168, 68,175,74,165,71,134,139,48,27,166
,77,146,158,231,83,111,229,122,60,211,133,230,220,105,92,41,55,46,245,40,244
,102,143,54, 65,25,63,161, 1,216,80,73,209,76,132,187,208, 89,18,169,200,196
,135,130,116,188,159,86,164,100,109,198,173,186, 3,64,52,217,226,250,124,123
,5,202,38,147,118,126,255,82,85,212,207,206,59,227,47,16,58,17,182,189,28,42
,223,183,170,213,119,248,152, 2,44,154,163, 70,221,153,101,155,167, 43,172,9
,129,22,39,253, 19,98,108,110,79,113,224,232,178,185, 112,104,218,246,97,228
,251,34,242,193,238,210,144,12,191,179,162,241, 81,51,145,235,249,14,239,107
,49,192,214, 31,181,199,106,157,184, 84,204,176,115,121,50,45,127, 4,150,254
,138,236,205,93,222,114,67,29,24,72,243,141,128,195,78,66,215,61,156,180
);
p[ 0 : 255 ] := p[ 256 : ];
OP AND = ( INT a, b )INT:
IF a >= 0
THEN ABS ( BIN a AND BIN b )
ELSE ABS ( NOT BIN ( - ( a + 1 ) ) AND BIN b )
FI # AND # ;
PROC fade = ( REAL t )REAL: ( t * t * t ) * ( t * ( t * 6 - 15 ) + 10 );
PROC linerp = ( REAL t, a, b )REAL: a + ( t * ( b - a ) );
PROC grad = ( INT hash, REAL x, y, z )REAL:
BEGIN
INT h = hash AND 15;
REAL u = IF h < 8 THEN x ELSE y FI;
REAL v = IF h < 4 THEN y ELIF h = 12 OR h = 14 THEN x ELSE z FI;
IF ( h AND 1 ) = 0 THEN u ELSE -u FI + IF ( h AND 2 ) = 0 THEN v ELSE -v FI
END # grad # ;
PROC perlin noise = ( REAL x in, y in, z in )REAL:
BEGIN
REAL x := x in, y := y in, z := z in;
INT xx = ENTIER x AND 255;
INT yy = ENTIER y AND 255;
INT zz = ENTIER z AND 255;
x -:= ENTIER x;
y -:= ENTIER y;
z -:= ENTIER z;
REAL u = fade( x );
REAL v = fade( y );
REAL w = fade( z );
INT a = p[ xx ] + yy;
INT aa = p[ a ] + zz;
INT ab = p[ a + 1 ] + zz;
INT b = p[ xx + 1 ] + yy;
INT ba = p[ b ] + zz;
INT bb = p[ b + 1 ] + zz;
linerp( w
, linerp( v
, linerp( u
, grad( p[ aa ], x, y, z )
, grad( p[ ba ], x - 1, y, z )
)
, linerp( u
, grad( p[ ab ], x, y - 1, z )
, grad( p[ bb ], x - 1, y - 1, z )
)
)
, linerp( v
, linerp( u
, grad( p[ aa + 1 ], x, y, z - 1 )
, grad( p[ ba + 1 ], x - 1, y, z - 1 )
)
, linerp( u
, grad( p[ ab + 1 ], x, y - 1, z - 1 )
, grad( p[ bb + 1 ], x - 1, y - 1, z - 1 )
)
)
)
END # perlin noise # ;
print( ( fixed( perlin noise( 3.14, 42, 7 ), -18, 15 ) ) )
END
</syntaxhighlight>
{{out}}
<pre>
0.136919958784000
</pre>
Line 509 ⟶ 595:
[https://easylang.dev/show/#cod=bZbdctpIEIXveYqu2qot2C0TzYxmJF3kSVK+AGxiyjZQBBykp893hBBIxLHRzOnuM6d/NGT/49m+2w9z0ZlLmblQWOWsYhXZAAbzGUC0KlkM5qrcfAhWmPd45JmFZC4LFjJLFYC30qrK4PEYPQx8Kg475hK4MOcF5lZEYwFeFZa8iTt6gioOJcYVFjjEWfAWiSrYByvhgN7llcVkpXDiUCxBUlMol9L4dRyA0SUeyoVlqEwiiErJCtEQEUXprNSZjsxIxHtL0q8wakB6XmdkFMJb7ixGI9LnPDDlMGcesmAxN45DS4ItEQ4JMjMrVMrKCs4jH4dwn5VWchZCk1KGv5JVebAmzJGsi5WVLJPOkAQiKuUGP3gwDG3V1BMkRZUCX6qODlQFnFV0ndM6RCtpE0ZHWCYd9BYBVEV+bEQPu2SCl0ZbvbqoChUqiyqFJZc8bKYCRFWa0VCpyFvTkulJOglmhdJjNOgooxG+HShTMlTCMSkFZo2c15RxegFcagRYZ2BO85OsUqosmVp66lHnKjUJCBInMYI4XIRMlqdjJU0DoWOeCvtc08qSByXQrlIRc9PU4+sqWTQcqkRupYYMYvVPLwcpUulcK8JxI21VQCKYQq9JUSYIgZQCKG1GXmJIG0GOFBxvFkkyix5SjUtU1zN7nqx3B9vYcQdtmpjZnnf13+88Ns+T+WR92q5svXh5taPNZT68Hk+HLbv/+r9p/5HsCeaZ/U9Ks2v0x+thj9/ClgOGBV5t4JKgRe/987B4sbfFrzc7W23NJeSN26PFPncvFFrQZt2imSFfC+eF3ujP0NeCXj86V9e75kPXGgHngesD19OIKwwdnh498kc5zcAhDh2aBxHpUcSQofiLiKFHOU50LKLqaxIe5YzKlz1WrSW7b+rTBe16ud1tfr3e93EBz/pjx5nntpXdyC17uL6HVz3c3MPnM/gl3mlf1+zr275p2De3/Uk0muBzW9+v67Zu8/t93TZtMovMNPsaTvfMx7IF3QXMruiqRf0N9T26vBH4nmB5IVgOCZb+ht4I3uXbvgWwuEsAKZPlReG7v9mXnX16Vu/d7M4r3LH4nmVa1xfHziu/4/IjrrFvHOnyV13TpmkdW680UueH6ga+xUijH2oc+JYjpf5vSu8juolsb5/fNm2fX93zpCq/+9ltG6jFbPboFsnozq1AyEx31fb0uf486usrm+wPm+2xG/Yw5xbmi6KY/GPt1arhzHS9ctFL1rod/iHGzx7owjA92zf+m6OsukU2d53X5+5L79M3vgllvF5Tq93H7hDg4F//kq6OBCb9XV7S+eQP Run it]
<syntaxhighlight>
Line 1,280 ⟶ 1,365:
static { for (int i=0; i < 256 ; i++) p[256+i] = p[i] = permutation[i]; }
}</syntaxhighlight>
=={{header|jq}}==
'''Adapted from [[#Wren|Wren]]'''
'''Works with jq, the C implementation of jq'''
'''Works with gojq, the Go implementation of jq'''
<syntaxhighlight lang="jq">
### Generic functions
# (-3.2|fraction) #=> -0.2
def fraction:
if . >= 0 then . - trunc
else - (-. | fraction)
end;
# For gojq
def div($y):
(. - (. % y)) / $y;
# Convert the input integer to a stream of 0s and 1s, least significant bit first
def bitwise:
recurse( if . >= 2 then div(2) else empty end) | . % 2;
# Inverse of bitwise:
def stream_to_integer(stream):
reduce stream as $c ( {power:1 , ans: 0};
.ans += ($c * .power) | .power *= 2 )
| .ans;
# . & 2^($n-1)
def bits($n):
stream_to_integer(limit($n; bitwise));
### Perlin Noise
def permutation: [
151, 160, 137, 91, 90, 15, 131, 13, 201, 95, 96, 53, 194, 233, 7, 225,
140, 36, 103, 30, 69, 142, 8, 99, 37, 240, 21, 10, 23, 190, 6, 148,
247, 120, 234, 75, 0, 26, 197, 62, 94, 252, 219, 203, 117, 35, 11, 32,
57, 177, 33, 88, 237, 149, 56, 87, 174, 20, 125, 136, 171, 168, 68, 175,
74, 165, 71, 134, 139, 48, 27, 166, 77, 146, 158, 231, 83, 111, 229, 122,
60, 211, 133, 230, 220, 105, 92, 41, 55, 46, 245, 40, 244, 102, 143, 54,
65, 25, 63, 161, 1, 216, 80, 73, 209, 76, 132, 187, 208, 89, 18, 169,
200, 196, 135, 130, 116, 188, 159, 86, 164, 100, 109, 198, 173, 186, 3, 64,
52, 217, 226, 250, 124, 123, 5, 202, 38, 147, 118, 126, 255, 82, 85, 212,
207, 206, 59, 227, 47, 16, 58, 17, 182, 189, 28, 42, 223, 183, 170, 213,
119, 248, 152, 2, 44, 154, 163, 70, 221, 153, 101, 155, 167, 43, 172, 9,
129, 22, 39, 253, 19, 98, 108, 110, 79, 113, 224, 232, 178, 185, 112, 104,
218, 246, 97, 228, 251, 34, 242, 193, 238, 210, 144, 12, 191, 179, 162, 241,
81, 51, 145, 235, 249, 14, 239, 107, 49, 192, 214, 31, 181, 199, 106, 157,
184, 84, 204, 176, 115, 121, 50, 45, 127, 4, 150, 254, 138, 236, 205, 93,
222, 114, 67, 29, 24, 72, 243, 141, 128, 195, 78, 66, 215, 61, 156, 180
];
def grad($hash; $x; $y; $z):
def bit2: nth(1; bitwise);
# Convert low 4 bits of hash code into 12 gradient directions:
( $hash|bits(4) ) as $h
| (if $h < 8 then $x else $y end) as $u
| (if $h < 4 then $y elif ($h == 12 or $h == 14) then $x else $z end) as $v
| (if ($h % 2 == 0) then $u else -$u end) +
(if (($h | bit2) == 0) then $v else -$v end) ;
def noise($x; $y; $z):
def p:
permutation as $p
| $p[:256] + [range(256;512) | $p[.-256]];
def fade:
. * . * . * (. * (. * 6 - 15) + 10) ;
def lerp($t; $a; $b): $a + $t * ($b - $a);
# Find unit cube that contains point
([$x,$y,$z] | map(floor | bits(8))) as [$xi, $yi, $zi]
# Find relative x, y, z of point in cube
| ([$x,$y,$z] | map(fraction)) as [$xx, $yy, $zz]
# Compute fade curves for each of xx, yy, zz
| ([$xx,$yy,$zz] | map(fade)) as [$u, $v, $w]
| p as $p
# Hash co-ordinates of the 8 cube corners
# and add blended results from 8 corners of cube
| ($p[$xi] + $yi) as $a
| ($p[$a] + $zi) as $aa
| ($p[$a + 1] + $zi) as $ab
| ($p[$xi + 1] + $yi) as $b
| ($p[$b] + $zi) as $ba
| ($p[$b + 1] + $zi) as $bb
| lerp($w;
lerp($v;
lerp($u;
grad($p[$aa]; $xx; $yy; $zz);
grad($p[$ba]; $xx - 1; $yy; $zz));
lerp($u;
grad($p[$ab]; $xx; $yy - 1; $zz);
grad($p[$bb]; $xx - 1; $yy - 1; $zz)));
lerp($v;
lerp($u;
grad($p[$aa + 1]; $xx; $yy; $zz - 1);
grad($p[$ba + 1]; $xx - 1; $yy; $zz - 1));
lerp($u;
grad($p[$ab + 1]; $xx; $yy - 1; $zz - 1);
grad($p[$bb + 1]; $xx - 1; $yy - 1; $zz - 1))) );
noise(3.14; 42; 7)
</syntaxhighlight>
{{output}}
<pre>
0.13691995878400012
</pre>
=={{header|Julia}}==
Line 2,702 ⟶ 2,899:
=={{header|Wren}}==
{{trans|Kotlin}}
<syntaxhighlight lang="
151, 160, 137, 91, 90, 15, 131, 13, 201, 95, 96, 53, 194, 233, 7, 225,
140, 36, 103, 30, 69, 142, 8, 99, 37, 240, 21, 10, 23, 190, 6, 148,
| |||