Find words with alternating vowels and consonants: Difference between revisions
Find words with alternating vowels and consonants (view source)
Revision as of 23:46, 21 June 2021
, 2 years agoAdded Quackery.
(Added Quackery.) |
|||
Line 2,025:
telekinesis teratogenic topologize unilateral
unimodular uninominal verisimilitude</pre>
=={{header|Quackery}}==
<lang Quackery>
[ [] swap ]'[ swap
witheach
[ dup nested
unrot over do
iff [ dip join ]
else nip ]
drop ] is filter ( [ --> [ )
[ [ 0
26 times
[ i^ char A +
bit | ]
26 times
[ i^ char a +
bit | ] ] constant ] is letters ( --> n )
[ [ 0 $ "AEIUOaeiou"
witheach [ bit | ] ]
constant ] is vowels ( --> n )
[ [ letters vowels ~ & ]
constant ] is consonants ( --> n )
[ true swap
witheach
[ bit letters & 0 =
if [ conclude not ] ] ] is onlyletters ( $ --> b )
[ stack [ ] ] is chartest ( $ --> b )
[ bit vowels & 0 > ] is isvowel ( c --> b )
[ bit consonants & 0 > ] is isconsonant ( c --> b )
forward is constest ( c --> b )
[ isvowel
' constest
chartest replace ] is voweltest ( c --> b )
[ isconsonant
' voweltest
chartest replace ] resolves constest ( c --> b )
[ behead isvowel iff
[ ' constest ]
else [ ' voweltest ]
chartest put
true swap witheach
[ chartest share do
not if
[ conclude not ] ] ] is alternating ( $ --> b )
[ dup size 10 < iff
[ drop false ] done
dup onlyletters not iff
[ drop false ] done
alternating ] is allcriteria ( $ --> b )
$ "rosetta/unixdict.txt" sharefile
drop nest$
filter allcriteria
80 wrap$</lang>
{{out}}
<pre>aboriginal apologetic bimolecular borosilicate calorimeter capacitate capacitive
capitoline capitulate caricature colatitude coloratura colorimeter debilitate
decelerate decolonize definitive degenerate deliberate demodulate denominate
denotative deregulate desiderata desideratum dilapidate diminutive epigenetic
facilitate hemosiderin heretofore hexadecimal homogenate inoperative judicature
latitudinal legitimate lepidolite literature locomotive manipulate metabolite
nicotinamide oratorical paragonite pejorative peridotite peripatetic polarimeter
recitative recuperate rehabilitate rejuvenate remunerate repetitive reticulate
savonarola similitude solicitude tananarive telekinesis teratogenic topologize
unilateral unimodular uninominal verisimilitude
</pre>
=={{header|Raku}}==
| |||