Erdős-primes: Difference between revisions
→{{header|Palo Alto Tiny BASIC}}: Added a solution.
(→{{header|PL/0}}: Added a solution.) |
(→{{header|Palo Alto Tiny BASIC}}: Added a solution.) |
||
Line 282:
25 2437
7875 999721
</pre>
==={{header|Palo Alto Tiny BASIC}}===
{{trans|Tiny BASIC|Removed overlapping loops.}}
Without the stretch goal because numbers are limited to signed 16-bit integers.
<syntaxhighlight lang="basic">
10 REM ERDOS-PRIMES
20 LET P=2,C=1
30 PRINT C," ",P
40 FOR P=3 TO 2500 STEP 2
50 LET Z=P;GOSUB 1000
60 IF A=0 GOTO 160
70 REM F = K!
80 LET K=1,F=1,Z=P-F
90 IF Z<0 GOTO 150
100 GOSUB 1000
110 IF A=1 GOTO 150
120 LET K=K+1,F=F*K,Z=P-F
130 IF Z<0 GOTO 150
140 GOTO 100
150 IF Z<0 LET C=C+1;PRINT C," ",P
160 NEXT P
170 STOP
980 REM PRIMALITY OF Z BY TRIAL DIVISION
990 REM RESULT IS IN A
1000 LET A=0
1010 IF Z=2 LET A=1;RETURN
1020 IF Z<3 RETURN
1030 LET Y=2
1040 IF (Z/Y)*Y=Z RETURN
1050 IF Y*Y>=Z LET A=1;RETURN
1060 LET Y=Y+1
1070 GOTO 1040
1080 RETURN
</syntaxhighlight>
{{out}}
<pre>
1 2
2 101
3 211
4 367
5 409
6 419
7 461
8 557
9 673
10 709
11 769
12 937
13 967
14 1009
15 1201
16 1259
17 1709
18 1831
19 1889
20 2141
21 2221
22 2309
23 2351
24 2411
25 2437
</pre>
| |||