Discordian date: Difference between revisions

=={{header|PL/M}}==

{{works with|8080 PL/M Compiler}} ... under CP/M (or an emulator)

<br>

Based on:{{Trans|MAD}}...via Algol W

<syntaxhighlight lang="plm">

100H: /* DISCORDIAN DATE CALCULATION - TRANSLATION OF MAD (VIA ALGOL W) */

/* CP/M SYSTEM CALL AND I/O ROUTINES */

BDOS: PROCEDURE( FN, ARG ); DECLARE FN BYTE, ARG ADDRESS; GOTO 5; END;

PR$CHAR: PROCEDURE( C ); DECLARE C BYTE; CALL BDOS( 2, C ); END;

PR$STRING: PROCEDURE( S ); DECLARE S ADDRESS; CALL BDOS( 9, S ); END;

PR$NL: PROCEDURE; CALL PR$CHAR( 0DH ); CALL PR$CHAR( 0AH ); END;

PR$NUMBER: PROCEDURE( N ); /* PRINTS A NUMBER IN THE MINIMUN FIELD WIDTH */

DECLARE N ADDRESS;

DECLARE V ADDRESS, N$STR ( 6 )BYTE, W BYTE;

V = N;

W = LAST( N$STR );

N$STR( W ) = '$';

N$STR( W := W - 1 ) = '0' + ( V MOD 10 );

DO WHILE( ( V := V / 10 ) > 0 );

N$STR( W := W - 1 ) = '0' + ( V MOD 10 );

END;

CALL PR$STRING( .N$STR( W ) );

END PR$NUMBER;

/* TASK */

DECLARE HOLY5 ( 5 )ADDRESS;

DECLARE HOLY50 ( 5 )ADDRESS;

DECLARE DISDAY ( 5 )ADDRESS;

DECLARE DISSSN ( 5 )ADDRESS;

DECLARE MLENGT ( 13 )ADDRESS

INITIAL( 0, 0, 31, 59, 90, 120

, 151, 181, 212, 243, 273, 304, 334

);

HOLY5 (0) = .'MUNG$'; HOLY5 (1) = .'MOJO$'; HOLY5 (2) = .'SYA$';

HOLY5 (3) = .'ZARA$'; HOLY5 (4) = .'MALA$';

HOLY50(0) = .'CHAO$'; HOLY50(1) = .'DISCO$'; HOLY50(2) = .'CONFU$';

HOLY50(3) = .'BURE$'; HOLY50(4) = .'AF$';

DISDAY(0) = .'SWEETMORN$'; DISDAY(1) = .'BOOMTIME$';

DISDAY(2) = .'PUNGENDAY$'; DISDAY(3) = .'PRICKLE-PRICKLE$';

DISDAY(4) = .'SETTING ORANGE$';

DISSSN(0) = .'CHAOS$'; DISSSN(1) = .'DISCORD$'; DISSSN(2) = .'CONFUSION$';

DISSSN(3) = .'BUREAUCRACY$'; DISSSN(4) = .'THE AFTERMATH$';

/* PRINTS THE DISWCORDIAN DATE GMONTH/GDAY/GYEAR */

/* GMONTH/GDAY/GYEAR SHOULD BE IN THE GREGORIAN CALENDAR */

PR$DISCORDIAN$DATE: PROCEDURE( GMONTH, GDAY, GYEAR );

DECLARE ( GMONTH, GDAY, GYEAR ) ADDRESS;

IF GMONTH = 2 AND GDAY = 29

THEN DO;

CALL PR$STRING( .'SAINT TIB''S DAY IN THE Y.O.L.D. $' );

CALL PR$NUMBER( GYEAR + 1166 );

END;

ELSE DO;

DECLARE ( YRDAY, SEASON, DAY, WKDAY ) ADDRESS;

YRDAY = MLENGT(GMONTH)+GDAY;

SEASON = YRDAY / 73;

DAY = YRDAY-SEASON*73;

WKDAY = (YRDAY-1) MOD 5;

CALL PR$STRING( DISDAY(WKDAY) );

CALL PR$STRING( .', DAY $' );

CALL PR$NUMBER( DAY );

CALL PR$STRING( .' OF $' );

CALL PR$STRING( DISSSN(SEASON) );

CALL PR$STRING( .' IN THE Y.O.L.D $' );

CALL PR$NUMBER( GYEAR + 1166 );

IF DAY = 5 THEN DO;

CALL PR$NL;

CALL PR$STRING( .'CELEBRATE $' );

CALL PR$STRING( HOLY5(SEASON) );

CALL PR$STRING( .'DAY$' );

END;

ELSE IF DAY = 50 THEN DO;

CALL PR$NL;

CALL PR$STRING( .'CELEBRATE $' );

CALL PR$STRING( HOLY50(SEASON) );

CALL PR$STRING( .'FLUX$' );

END;

END;

CALL PR$NL;

END PR$DISCORDIAN$DATE;

CALL PR$DISCORDIAN$DATE( 08, 15, 2017 ); CALL PR$NL;

CALL PR$DISCORDIAN$DATE( 12, 06, 2020 ); CALL PR$NL;

CALL PR$DISCORDIAN$DATE( 07, 12, 1969 ); CALL PR$NL;

CALL PR$DISCORDIAN$DATE( 01, 05, 2005 ); CALL PR$NL;

CALL PR$DISCORDIAN$DATE( 09, 26, 1995 ); CALL PR$NL;

EOF

</syntaxhighlight>

{{out}}

<pre>

BOOMTIME, DAY 8 OF BUREAUCRACY IN THE Y.O.L.D 3183

SETTING ORANGE, DAY 48 OF THE AFTERMATH IN THE Y.O.L.D 3186

PUNGENDAY, DAY 47 OF CONFUSION IN THE Y.O.L.D 3135

SETTING ORANGE, DAY 5 OF CHAOS IN THE Y.O.L.D 3171

CELEBRATE MUNGDAY

PRICKLE-PRICKLE, DAY 50 OF BUREAUCRACY IN THE Y.O.L.D 3161

CELEBRATE BUREFLUX

</pre>