Active object

Active object
You are encouraged to solve this task according to the task description, using any language you may know.

In object-oriented programming an object is active when its state depends on clock. Usually an active object encapsulates a task that updates the object's state. To the outer world the object looks like a normal object with methods that can be called from outside. Implementation of such methods must have a certain synchronization mechanism with the encapsulated task in order to prevent object's state corruption.

A typical instance of an active object is an animation widget. The widget state changes with the time, while as an object it has all properties of a normal widget.

The task

Implement an active integrator object. The object has an input and output. The input can be set using the method Input. The input is a function of time. The output can be queried using the method Output. The object integrates its input over the time and the result becomes the object's output. So if the input is K(t) and the output is S, the object state S is changed to S + (K(t₁) + K(t₀)) * (t₁ - t₀) / 2, i.e. it integrates K using the trapeze method. Initially K is constant 0 and S is 0.

In order to test the object:

1. set its input to sin (2pi f t), where the frequency f=0.5Hz. The phase is irrelevant.
2. wait 2s
3. set the input to constant 0
4. wait 0.5s

Verify that now the object's output is approximately 0s (the sine has the period of 2s). The accuracy of the result will depend on the OS scheduler time slicing and the accuracy of the clock.

Ada

<ada> with Ada.Calendar; use Ada.Calendar; with Ada.Numerics; use Ada.Numerics; with Ada.Numerics.Elementary_Functions; use Ada.Numerics.Elementary_Functions; with Ada.Text_IO; use Ada.Text_IO;

procedure Test_Integrator is

  type Func is access function (T : Time) return Float;

  function Zero (T : Time) return Float is
  begin
     return 0.0;
  end Zero;

  Epoch : constant Time := Clock;

  function Sine (T : Time) return Float is
  begin
     return Sin (Pi * Float (T - Epoch));
  end Sine;

  task type Integrator is
     entry Input  (Value : Func);
     entry Output (Value : out Float);
     entry Shut_Down;
  end Integrator;

  task body Integrator is
     K  : Func  := Zero'Access;
     S  : Float := 0.0;
     F0 : Float := 0.0;
     F1 : Float;
     T0 : Time  := Clock;
     T1 : Time;
  begin
     loop
        select
           accept Input (Value : Func) do
              K := Value;
           end Input;
        or accept Output (Value : out Float) do
              Value := S;
           end Output;
        or accept Shut_Down;
           exit;
        else
           T1 := Clock;
           F1 := K (T1);
           S  := S + 0.5 * (F1 + F0) * Float (T1 - T0);
           T0 := T1;
           F0 := F1;
        end select;
     end loop;
  end Integrator;

  I : Integrator;
  S : Float;

begin

  I.Input (Sine'Access);
  delay 2.0;
  I.Input (Zero'Access);
  delay 0.5;
  I.Output (S);
  Put_Line ("Integrated" & Float'Image (S) & "s");
  I.Shut_Down;

end Test_Integrator; </ada> Sample output:

Integrated-5.34100E-05s

E

def makeIntegrator() {
    var r := 0.0
    var dr := 0.0
    var t := timer.now()
    
    def update() {
        def t2 := timer.now()
        r += dr * (t2 - t) / 1000
        t := t2
    }
    
    var task() {
      update()
      task <- ()
    }
    task()
    
    def integrator {
        to input(new :float64) :void {
            dr := new
        }
        to output() :float64 {
            return r
        }
        to shutdown() {
            task := fn {}
        }
    }
    return integrator
}

def test() {
    def result
    def base := timer.now()
    def i := makeIntegrator()
    i.input(1)
    timer.whenPast(base + 2000, fn {
        i.input(0)
    })
    timer.whenPast(base + 2500, fn {
        i.input(0.5)
    })
    timer.whenPast(base + 3500, fn {
        i.input(0)
        bind result := i.output()
        i.shutdown()
    })
    return result
}

This integrator need not actually use any continuous background processing; it can compute only when interacted with. To do this, insert update() at the beginning of the input and output methods, and delete the definitions of task and shutdown.