View source for Minimum positive multiple in base 10 using only 0 and 1

=={{header|REXX}}==
<syntaxhighlight lang="rexx">/*REXX pgm finds minimum pos. integer that's a product of N that only has the digs 0 & 1*/
numeric digits 30;  w= length( commas( copies(1, digits())))   /*for formatting numbers.*/
parse arg list
if list==''  then list= 1..10  95..105 297
say center(' N ', 9, "─")      center(' B10 ', w, "─")      center(' multiplier ', w, "─")

       do i=1  for words(list)
       z= word(list, i);                      LO= z;    HI= z
       if pos(.., z)\==0  then parse var  z   LO  '..'  HI

          do n=LO  to HI;                             m= B10(n)
          say right(commas(n), 9)      right(commas(n*m), w)         left(commas(m), w)
          end   /*n*/
       end      /*i*/
exit 0                                           /*stick a fork in it,  we're all done. */
/*──────────────────────────────────────────────────────────────────────────────────────*/
commas: parse arg _;  do c=length(_)-3  to 1  by -3; _= insert(',', _, c); end;   return _
/*──────────────────────────────────────────────────────────────────────────────────────*/
B10: parse arg #;  inc= 1;                         start= 1;               L= length(#)
                            select
                            when verify(#, 10)==0  then return 1
                            when verify(#,  9)==0  then do;                start=
                                                            do k= 1  for 8
                                                            start= start || copies(k, L)
                                                            end   /*k*/
                                                        end
                            when #//2==0           then do;  start=5;  inc=  5;  end
                            when right(z, 1)==7    then do;  start=3;  inc= 10;  end
                            otherwise nop
                            end   /*select*/
     q= length(start)
     if q>digits()  then numeric digits q
                            do m=start  by  inc  until verify(p, 10)==0;   p= # * m
                            end   /*m*/
     return m</syntaxhighlight>
{{out|output|text=&nbsp; when using the default inputs:}}
<pre>
─── N ─── ───────────────── B10 ───────────────── ───────────── multiplier ──────────────
        1                                       1 1
        2                                      10 5
        3                                     111 37
        4                                     100 25
        5                                      10 2
        6                                   1,110 185
        7                                   1,001 143
        8                                   1,000 125
        9                             111,111,111 12,345,679
       10                                      10 1
       95                                 110,010 1,158
       96                              11,100,000 115,625
       97                              11,100,001 114,433
       98                                11000010 112245
       98                              11,000,010 112,245
       99                      111111111111111111 1122334455667789
       99                 111,111,111,111,111,111 1,122,334,455,667,789
      100                                     100 1
      101                                     101 1
      102                               1,000,110 9,805
      103                              11,100,001 107,767
      104                               1,001,000 9,625
      105                                 101,010 962
      297               1,111,011,111,111,111,111 3,740,778,151,889,263
      576                     111,111,111,000,000 192,901,234,375
      594              11,110,111,111,111,111,110 18,703,890,759,446,315
      891               1,111,111,111,111,111,011 1,247,038,284,075,321
      909               1,011,111,111,111,111,111 1,112,333,455,567,779
      999     111,111,111,111,111,111,111,111,111 111,222,333,444,555,666,777,889
</pre>