View source for Fusc sequence

=={{header|jq}}==
'''Adapted from [[#Wren|Wren]]'''
{{works with|jq}}
'''Works with gojq, the Go implementation of jq'''

'''Preliminaries'''
<syntaxhighlight lang="jq"># input should be a non-negative integer
def commatize:
  # "," is 44
  def digits: tostring | explode | reverse;
  [foreach digits[] as $d (-1; .+1;
     (select(. > 0 and . % 3 == 0)|44), $d)]
  | reverse | implode  ; 

def lpad($len): tostring | ($len - length) as $l | (" " * $l)[:$l] + .;</syntaxhighlight>
'''Fusc Sequence'''
<syntaxhighlight lang="jq"># Save space by truncating the beginning of the array
def fusc:
   0, 1,
   foreach range(2; infinite) as $n ([0, 1];
      ($n % 2 == 0) as $even
      | if $even then . + [.[1]] else.[1:] + [.[1] + .[2]] end;
      .[-1] );

# Report first longest
def fusc( $mx ):
  def l: commatize|lpad(10);

  foreach limit( $mx; fusc ) as $f ({ maxLen: 0, n: 0 };
    .emit = false
    | ("\($f)"|length) as $len
    | if $len > .maxLen
      then .maxLen = $len
      | .emit = "\(.n|l)  \($f|commatize)"
      else .
      end
      | .n += 1
      ;
      select(.emit).emit
    );

# First $first numbers in the fusc sequence
61 as $first
| 2e6 as $mx
| "The first \($first) numbers in the fusc sequence are:",
   ([limit($first; fusc)]| map(tostring) | join(" ")) ,

   "\nFirst terms longer than any previous ones for indices < \($mx + 0 |commatize):",
   "     Index  Value",
   fusc($mx)</syntaxhighlight>
{{out}}
<pre>
The first 61 numbers in the fusc sequence are:
0 1 1 2 1 3 2 3 1 4 3 5 2 5 3 4 1 5 4 7 3 8 5 7 2 7 5 8 3 7 4 5 1 6 5 9 4 11 7 10 3 11 8 13 5 12 7 9 2 9 7 12 5 13 8 11 3 10 7 11 4

First terms longer than any previous ones for indices < 20,000,000:
     Index  Value
         0  0
        37  11
     1,173  108
    35,499  1,076
   699,051  10,946
19,573,419  103,682

</pre>