Iccanobif primes: Difference between revisions
Added PL/M
mNo edit summary |
(Added PL/M) |
||
Line 796:
</pre>
Very slow, that's as far as I was prepared to listen to it whine away...
=={{header|PL/M}}==
{{works with|8080 PL/M Compiler}} ... under CP/M (or an emulator)
As 8080 PL/M only handles 8 and 16 bit unsigned integers, this stops when the reversed number would be over 65530 and so finds only 8 Iccanobif primes.
<syntaxhighlight lang="plm">
100H: /* SHOW SOME PRIME ICCANOBIF (REVERSED FIBONACCI) NUMBERS */
/* CP/M BDOS SYSTEM CALL AND I/O ROUTINES */
BDOS: PROCEDURE( FN, ARG ); DECLARE FN BYTE, ARG ADDRESS; GOTO 5; END;
PR$CHAR: PROCEDURE( C ); DECLARE C BYTE; CALL BDOS( 2, C ); END;
PR$STRING: PROCEDURE( S ); DECLARE S ADDRESS; CALL BDOS( 9, S ); END;
PR$NL: PROCEDURE; CALL PR$CHAR( 0DH ); CALL PR$CHAR( 0AH ); END;
PR$NUMBER: PROCEDURE( N ); /* PRINTS A NUMBER IN THE MINIMUN FIELD WIDTH */
DECLARE N ADDRESS;
DECLARE V ADDRESS, N$STR ( 6 )BYTE, W BYTE;
V = N;
W = LAST( N$STR );
N$STR( W ) = '$';
N$STR( W := W - 1 ) = '0' + ( V MOD 10 );
DO WHILE( ( V := V / 10 ) > 0 );
N$STR( W := W - 1 ) = '0' + ( V MOD 10 );
END;
CALL PR$STRING( .N$STR( W ) );
END PR$NUMBER;
/* RETURNS TRUE IF N IS PRIME, FALSE OTHERWISE, USES TRIAL DIVISION */
IS$PRIME: PROCEDURE( N )BYTE;
DECLARE N ADDRESS;
DECLARE PRIME BYTE;
IF N < 3 THEN PRIME = N = 2;
ELSE IF N MOD 3 = 0 THEN PRIME = N = 3;
ELSE IF N MOD 2 = 0 THEN PRIME = 0;
ELSE DO;
DECLARE ( F, F2, TO$NEXT ) ADDRESS;
PRIME = 1;
F = 5;
F2 = 25;
TO$NEXT = 24; /* NOTE: ( 2N + 1 )^2 - ( 2N - 1 )^2 = 8N */
DO WHILE F2 <= N AND PRIME;
PRIME = N MOD F <> 0;
F = F + 2;
F2 = F2 + TO$NEXT;
TO$NEXT = TO$NEXT + 8;
END;
END;
RETURN PRIME;
END IS$PRIME;
/* TASK */
DECLARE ( PREV, CURR, NEXT, V, R ) ADDRESS;
DECLARE MORE BYTE;
PREV = 0;
CURR = 1;
MORE = 1;
DO WHILE MORE;
NEXT = PREV + CURR;
/* REVERSE THE DIGITS OF NEXT, STOP IF THE RESULT WOULD BE > 65530 */
R = 0;
V = NEXT;
DO WHILE V > 0 AND MORE;
R = ( R * 10 ) + V MOD 10;
V = V / 10;
IF R > 6553 AND V <> 0 THEN MORE = 0;
END;
IF MORE THEN DO;
/* THE REVERSE OF N WILL FIT 16 BITS */
PREV = CURR;
CURR = NEXT;
IF IS$PRIME( R ) THEN DO;
CALL PR$CHAR( ' ' );CALL PR$NUMBER( R );
END;
END;
END;
EOF
</syntaxhighlight>
{{out}}
<pre>
2 3 5 31 43 773 7951 64901
</pre>
=={{header|Python}}==
| |||